topic Re: Creating a single variable from multiple variables in New SAS User

Creating a single variable from multiple variables

aowais — Mon, 04 Feb 2019 20:43:02 GMT

Hi,

I am trying to create a binary variable based on the responses in 8 other variables. I'm currently using the following code, which is working, but I was wondering if there is a better way to do this, such as using arrays?

data two; set one;
if co7_1 = 1 or co7_2 = 1 or co7_3 = 1 or co7_4 = 1 or co7_5 = 1 or
co7_6 = 1 or co7_7 = 1 or co7_8= 1 then public_care = 1;
else public_care = 0;
run;

Re: Creating a single variable from multiple variables

novinosrin — Mon, 04 Feb 2019 20:45:28 GMT

data two; set one;
/*if co7_1 = 1 or co7_2 = 1 or co7_3 = 1 or co7_4 = 1 or co7_5 = 1 or*/
/*co7_6 = 1 or co7_7 = 1 or co7_8= 1 then public_care = 1;*/
/*else public_care = 0;*/

array t(*) co7_1--co7_8;
public_care= max(of t(*))=1  ;
run;

Re: Creating a single variable from multiple variables

Reeza — Mon, 04 Feb 2019 20:51:52 GMT

Do you really need an array here?

Re: Creating a single variable from multiple variables

novinosrin — Mon, 04 Feb 2019 20:54:03 GMT

No but @PaigeMiller demonstrated many times to avoid var: lists as that could lead to some ambiguity which made sense and henceforth I am in agreement to that best practice

Let me see if I can find that thread

Re: Creating a single variable from multiple variables

aowais — Mon, 04 Feb 2019 20:54:48 GMT

Thanks, but this results in all values for public_care = 0...

Re: Creating a single variable from multiple variables

novinosrin — Mon, 04 Feb 2019 20:56:10 GMT

Hi @aowais here is a demo

data one;
array t(*) co7_1-co7_8 (7*0 1);
run;

data two;
set one;
array t(*) co7_1--co7_8;
public_care= max(of t(*))=1  ;
run;

co7_1	co7_2	co7_3	co7_4	co7_5	co7_6	co7_7	co7_8	public_care
0	0	0	0	0	0	0	1	1

Re: Creating a single variable from multiple variables

ballardw — Mon, 04 Feb 2019 21:21:14 GMT

@aowais wrote:
Thanks, but this results in all values for public_care = 0...

Please show the exact code you ran from the log. It is very easy to make a typo that may do that but without your code we can't tell where.

And some example input values for the variables that generate 0.

Re: Creating a single variable from multiple variables

PaigeMiller — Mon, 04 Feb 2019 21:27:19 GMT

@Reeza wrote:
Do you really need an array here?

Hello, @novinosrin

I think @Reeza was referring to the fact that you can use

public_care= max(of co7_1-co7_8)=1  ;

and no arrays are needed.

Re: Creating a single variable from multiple variables

novinosrin — Mon, 04 Feb 2019 21:29:15 GMT

ah ok

Re: Creating a single variable from multiple variables

Reeza — Mon, 04 Feb 2019 21:38:40 GMT

@novinosrin I understand your comment, but if the array declaration is the same as in the OF there's no need for the array declaration. Unless you're using it more than once, then I'll create it because I'm a lazy typist.

Re: Creating a single variable from multiple variables

novinosrin — Mon, 04 Feb 2019 21:41:34 GMT

got it. thick brains didn't get that insight at first until quantmiller clarified. I am even more convinced our search algorithm is paigerank algorithm. 🙂

Re: Creating a single variable from multiple variables

Astounding — Mon, 04 Feb 2019 22:14:57 GMT

Without knowing the range of values these variables take on, there is no way to know whether the codes are equivalent. It's possible that the max value for some of the variables is 3 instead of 1. That generates a very different outcome.

You could probably switch to this instead:

public_care = (whichn(1, of col7_1-col7_8) > 0);

It's untested, but looks about right.

Re: Creating a single variable from multiple variables

aowais — Tue, 05 Feb 2019 00:14:14 GMT

This worked! Thank you! You were right about the values being the issue. The values included 1, 2, 555 and some missing.