topic Re: compress single,double quotes,comma,brackets in New SAS User

compress single,double quotes,comma,brackets

SASPhile — Mon, 31 Dec 2018 16:53:36 GMT

How to compress single,double quotes,comma,brackets so the text is not completely compressed

I have text that will be as below:

"abc,'abc' (abc) "abc"

so would like to make it to as

abc abc abc abc

Re: compress single,double quotes,comma,brackets

SuzanneDorinski — Mon, 31 Dec 2018 17:34:08 GMT

You can use TRANSLATE to change the characters to spaces. You can use COMPBL to change multiple spaces to one space. You can use STRIP to remove space at the end.

data test;
  length have $ 25;
  input have 1 - 25;
  want = strip(
         compbl(
                translate(have,' ','"',
                               ' ',"'",
                               ' ','(',
                               ' ',')',
                               ' ',',')
                )
               );
  length_of_want=length(want);
  datalines;
"abc,'abc' (abc) "abc"
(abc) "abc" 'abc' abc,
(abc)(abc)(abc)((abc))
(((abc,)))"abc"'abc'
  ;
run;

proc print data=test;
run;

Re: compress single,double quotes,comma,brackets

Tom — Mon, 31 Dec 2018 17:50:09 GMT

Great answer.

Note that the TRANSLATE function will take longer strings, so no need to make multiple TO/FROM pairs. Plus it will pad out short TO strings with spaces. Also STRIP() can be simplified to LEFT(). When the result is assigned to another variable the value will be padded on the right with spaces anyway.

want = compbl(left(translate(have,' ','(",'')')));

Re: compress single,double quotes,comma,brackets

kiranv_ — Mon, 31 Dec 2018 20:11:26 GMT

same idea as @SuzanneDorinski. You can also use prxchange

[ ] --- anything mentioned in square bracket will be replace by space

data test;
  length have $ 25;
  input have 1 - 25;
  want = compbl(prxchange('s/["'')(,]+/ /',-1, have));
  datalines;
"abc,'abc' (abc) "abc"
(abc) "abc" 'abc' abc,
(abc)(abc)(abc)((abc))
(((abc,)))"abc"'abc'
  ;
run;

Re: compress single,double quotes,comma,brackets

Reeza — Tue, 01 Jan 2019 01:11:37 GMT

  want = compress(have, , 'kas');

Use the modifiers,

K - keeps characters

a - alphabetic

s - spaces, tabs etc.

RTM for more details:

https://documentation.sas.com/?cdcId=pgmmvacdc&cdcVersion=9.4&docsetId=lefunctionsref&docsetTarget=n0fcshr0ir3h73n1b845c4aq58hz.htm&locale=en#n1mi06lpn9ak5yn14q584vlzg32v

@SASPhile wrote:

How to compress single,double quotes,comma,brackets so the text is not completely compressed

I have text that will be as below:

"abc,'abc' (abc) "abc"

so would like to make it to as

abc abc abc abc

Re: compress single,double quotes,comma,brackets

novinosrin — Wed, 02 Jan 2019 00:25:08 GMT

Nice and interesting question to experiment various ideas


data test;
  input have $ 1 - 25;
   length want  $ 25;
  array t(99) $;
  j=countw(compress(have),,'p'); 
  do _n_=1 to j;
  t(_n_)=scan(compress(have),_n_,,'p');
  end;
  want=catx(' ',of t(*));
  drop j t:;
  datalines;
"abc,'abc' (abc) "abc"
(abc) "abc" 'abc' abc,
(abc)(abc)(abc)((abc))
(((abc,)))"abc"'abc'
  ;
run;

Re: compress single,double quotes,comma,brackets

novinosrin — Wed, 02 Jan 2019 00:41:53 GMT

Hi @Reeza Happy new year to you and others in the thread/sas communities.

I am afraid your

  want = compress(have, , 'kas');

will not quite meet the delimiter constraints in cases like "abc,'abc' (abc) "abc" for the reason there is no space in the highligted postion and so compress can't keep space if that doesn't exist. And most likely the same case for the 4th record and beyond. That's perhaps why @SuzanneDorinski 's strategy of replace and compbl makes sense. My 2 cents

Have great year ahead.

Re: compress single,double quotes,comma,brackets

Reeza — Wed, 02 Jan 2019 00:49:10 GMT

No it won't but the OP asked for a COMPRESS solution and this was the closest I could find. I suspect the original data is JSON or XML and that would be better overall, but that's just a guess.

Re: compress single,double quotes,comma,brackets

novinosrin — Wed, 02 Jan 2019 00:52:46 GMT

Ah ok, It's cool. I really like your crispy techniques and do take notes.

Re: compress single,double quotes,comma,brackets

novinosrin — Wed, 02 Jan 2019 00:59:07 GMT

Sets of 3 letters is obviously not real, so just for experimental fun


data test;
  input have $ 1 - 25;
   length want  $ 25;
  array t(99) $3;
  call pokelong(compress(have,,'ka'),addrlong(t(1)),25); 
  want=catx(' ',of t(*));
  drop t:;
  datalines;
"abc,'abc' (abc) "abc"
(abc) "abc" 'abc' abc,
(abc)(abc)(abc)((abc))
(((abc,)))"abc"'abc'
"abc,'abc' (abc) "abc"
  ;
run;

Re: compress single,double quotes,comma,brackets

SASPhile — Fri, 25 Jan 2019 19:09:44 GMT

I try to introduce single quote inside the [] and it leads to unbalanced quotes. how to replace a single quote along with other charcters in the square bracts?
like abc's

Re: compress single,double quotes,comma,brackets

SASPhile — Fri, 25 Jan 2019 19:09:54 GMT

I try to introduce single quote inside the [] and it leads to unbalanced quotes. how to replace a single quote along with other charcters in the square bracts?
like abc's

Re: compress single,double quotes,comma,brackets

kiranv_ — Sat, 26 Jan 2019 00:19:04 GMT

it does work for abc's. try out below code

data test;
  length have $ 25;
  input have 1 - 25;
  want = compbl(prxchange('s/["'')(,]+/ /',-1, have));
  datalines;
"abc,'abc' (abc) "abc"
(abc) "abc" 'abc' abc,
(abc)(abc)(abc)((abc))
(((abc,)))"abc"'abc'
abc's
  ;
run;