topic Re: how to generate this string in New SAS User

how to generate this string

JP1234 — Fri, 04 Jan 2019 23:32:00 GMT

start='01feb2017'd;

end='05may2018'd;

I want to generate a string

IND_FEB17,IND_MAR17, IND_APR17, IND_MAY17,.....IND_ARP18, IND_MAY18

how to use a marcro to do that?

Thanks.

Jeff

Re: how to generate this string

novinosrin — Sat, 05 Jan 2019 00:12:21 GMT

Very simple with datastep syntax than macro syntax IMHO

data w;
do i=0 to intck('month','01feb2017'd,'05may2018'd);
list=catx('_','IND',put(intnx('month','01feb2017'd,i),monyy.));
output;
end;
drop i;
run;

proc sql;
select list into :list separated by ','
from w;
quit;
%put &=list;

Re: how to generate this string

novinosrin — Sat, 05 Jan 2019 00:08:49 GMT

You can macrotise the above with a macro wrapper like


dm log 'clear';
%macro t(start='01feb2017'd,end='05may2018'd);
%global list;
data w;
do i=0 to intck('month',&start,&end);
list=catx('_','IND',put(intnx('month',&start,i),monyy.));
output;
end;
drop i;
run;
proc sql noprint;
select list into :list separated by ','
from w;
quit;
%mend t;
%t
%put list=&list;

Re: how to generate this string

ballardw — Sat, 05 Jan 2019 00:23:35 GMT

It may help to tell us how you intend to use the resulting string.

If it is supposed to represent a list of data sets or variables you may be able to us list notation such as

IND_: all variables or datasets that start with ind_

Ind_feb17 - ind_may18 possibly, depends on actual values of other dataset names or variables as month names or abbreviations are a not well thought out value for sorting/selection in order

ind_feb17 -- ind_may18 (adjacent variables in a set)

Re: how to generate this string

mkeintz — Sat, 05 Jan 2019 05:42:01 GMT

I agree with @ballardw that you might get more benefit from the forum if you let us know why you need this list. There may be many shortcuts that don't require itemizing the elements of the list.

However, this can be done fairly directly in a macro:

%macro monyy_list(prefix=,start=,end=);
  %global strng;
  %do d=%sysfunc(inputn(&start,date9.)) %to %sysfunc(inputn(&end,date9.));
    %let strng=&strng &prefix%sysfunc(putn(&d,monyy5.));
    %let d=%sysfunc(intnx(month,&d,1));
  %end;
%mend monyy_list;

%monyy_list(prefix=IND_,start=01feb2017,end=05may2018);
%put &=strng;

The %sysfunc macro function is a way to invoke regular SAS functions in the macro environment. In this case,

The INPUTN function reads a value as if into a numeric variable.
The PUTN function write a number as text according to the specific format.
The INTNX function advances the date value (in macrovar D) by 1 month.

Re: how to generate this string

Ksharp — Sat, 05 Jan 2019 10:41:14 GMT

data x;
start='01feb2017'd;
end='05may2018'd;
length want $ 800;
do i=start to end ;
 if month(i) ne month then do;
   want=catx(',',want,cats('IND_',put(i,monyy5.)));
 end;
 month=month(i);
end;

put want=;
run;

Re: how to generate this string

PeterClemmensen — Sat, 05 Jan 2019 11:55:48 GMT

I'm interested. Why do you want a string like that?

Re: how to generate this string

JP1234 — Sun, 06 Jan 2019 23:07:23 GMT

Thank you very much. It works!

The string contains field names form a dateset which is updated monthly with a new field name added to it.

Jeff

Re: how to generate this string

JP1234 — Sun, 06 Jan 2019 23:09:23 GMT

Thanks! Perfect!

Re: how to generate this string

JP1234 — Sun, 06 Jan 2019 23:12:33 GMT

Thanks!

Re: how to generate this string

andreas_lds — Mon, 07 Jan 2019 08:27:33 GMT

@JP1234 wrote:

Thank you very much. It works!

The string contains field names form a dateset which is updated monthly with a new field name added to it.

Jeff

Adding fields every month is only necessary if the data is stored in variable-names. That is bad design and fixing it almost always allows easier using of the data.