topic Re: Conditional sum in New SAS User

Conditional sum

NewUsrStat — Tue, 19 May 2026 18:51:52 GMT

Hi guys,

suppose to have the following dataset:

data DB;
  input ID :$20. Flag :$20. Observation;
cards;
0001  Y  .
0001  N  1
0001  N  .
0001  N  1
0002  N  1
0002  N  1
0002  N  1
0002  N  .

...;

Is there a way to sum all "Observation(s)" =1 but only for IDs having at least one Flag = "Y"?

Desired output: sum = 1

Thank you in advance

Re: Conditional sum

Quentin — Tue, 19 May 2026 19:01:39 GMT

Can you please show the output you want?

If you want the same dataset, with a sum added, you could use a double-DOW loop, e.g.

data want ;
   do until(last.id) ;
     set db ;
     by id ;
     if flag='Y' then _flagged=1 ;
     _sum=sum(observation,_sum,0) ;
   end ;
   if _flagged then mysum=_sum ;
   do until(last.id) ;
     set db ;
     by id ;
     output ;
  end ;
run ;

Re: Conditional sum

NewUsrStat — Tue, 19 May 2026 19:36:01 GMT

Thank you very much for your help. I just need the sum stored in an output db since the sum should refer to all IDs with at least one value of "Flag = Y" and not in particular to one or another ID.

Re: Conditional sum

Tom — Tue, 19 May 2026 19:55:14 GMT

This is something that SQL syntax would make it easy to express.

You describe it as a SUM but to me it looks more like a COUNT.

create table want as 
select count(distinct id) as n_ids_flagged 
  from have 
  where observation=1
    and id in (select id from have where flag='Y')
;

Re: Conditional sum

Quentin — Tue, 19 May 2026 19:51:05 GMT

From your example data, shouldn't the answer be 2 rather than 1?

You could still use a DOW-loop approach to flag the IDs of interest, then do the summing of the flagged records:

data want (keep=mysum);
   do until(last.id) ;
     set db ;
     by id ;
     if flag='Y' then _flagged=1 ;
   end ;
   do until(last.id) ;
     set db end=last ;
     by id ;
     if _flagged then mysum++observation;
  end ;
  if last then output ;
run ;

Or via SQL:

proc sql ;
  create table want as 
  select sum(observation) as mysum
  from
    (select id, observation
      from db
      group by id
      having max(flag)='Y'
    )
 ;
quit ;

Re: Conditional sum

yabwon — Tue, 19 May 2026 20:38:22 GMT

I think it can be done with one data pass:

data DB;
  input ID :$20. Flag :$20. Observation;
cards;
0001  Y  .
0001  N  1
0001  N  .
0001  N  1
0002  N  1
0002  N  1
0002  N  1
0002  N  .
0003  N  .
0003  N  1
0003  Y  .
0003  N  1
;
run;

data want;
  set db end=_E_;
  by id;
  if first.id then do; s=0; check=0; end;
  s + (Observation=1);
  check + (Flag="Y");
  if last.id and check then sum+s;
  if _E_;
run;
proc print data=want;
run;

Re: Conditional sum

yabwon — Tue, 19 May 2026 20:46:26 GMT

I think even almost "unconditionall" 😄

data want2;
  set db end=_E_;
  by id;
  
  s=s*(^first.id); 
  check=check*(^first.id);

  s + (Observation=1);
  check + (Flag="Y");
  sum+s*(last.id*check);

  if _E_;
run;
proc print data=want2;
run;

Re: Conditional sum

Quentin — Tue, 19 May 2026 21:11:32 GMT

I like it, Bart 😁

Since OP hints that there could be more than one record for an ID with flag='Y', perhaps:

check + (Flag="Y");

Should be:

check + ((Flag="Y") and (Not check));

Re: Conditional sum

yabwon — Wed, 20 May 2026 09:17:44 GMT

in this case we can do it like @hashman :

^^check

check&1

{EDIT:} or even just

& check

data want2;
  set db end=_E_;
  by id;
  
  s=s*(^first.id); 
  check=check*(^first.id);

  s + (Observation=1);
  check + (Flag="Y");
  sum+s*(last.id*^^check);
  /* sum+s*(last.id*check&1); */
  /* sum+s*(last.id & check); */

  if _E_;
run;
proc print data=want2;
run;

Bart