topic Re: Macro within Macro in New SAS User

Macro within Macro

trevand — Sat, 18 Jan 2025 03:55:17 GMT

To create indicators that equal to 1 I have to check if 20 variables have certain strings. So for instance if the variables VAR_1 through VAR_2 have "A1" "A2" "A3" I want to create testA=1. I am trying the following code but it doesn't work.

%let testA=("A1" "A2" "A3");
%let testB=("B1" "B2" "B3");


data NEED;
set HAVE;

%let var_list = TESTA TESTB;
%local i var;
%do i=1 %to %sysfunc(countw(&var_list.));
%let var = %scan(&var_list., &i.);

array cond {20} VAR_1-VAR_20;
do i=1 to dim (cond);
do j=1 to countw('&&&var..', ',');
if (cond {i} in &&&var..) the do;
&var.=1;
end;
end;
end;

%end;
%mend;
%var_list;

run;

Re: Macro within Macro

PaigeMiller — Sat, 18 Jan 2025 08:31:35 GMT

First, you have not shown us a macro, because there is no %MACRO statement. So that needs to be corrected.

When code doesn't work, saying "it doesn't work" and not providing more details is never helpful. We need to see the evidence that it doesn't work, that evidence is likely in the SAS log.

When you are trying to debug a macro, turn on the macro debugging command by running this line of code

options mprint;

and then run your macro again, and look at the log. See if you can figure out from the log where the problem is and how to fix it. If you still need help, show us the ENTIRE log by copying the log as text and pasting it into the window that appears when you click on the </> icon. DO NOT SKIP THIS STEP.

Why is the title "macro within macro" when your code doesn't show anything like that?

Re: Macro within Macro

Astounding — Sat, 18 Jan 2025 10:01:54 GMT

A general principle: get your code working without macro language. Once that is complete, convert your code to a macro. Looking at your program, a couple of things would stand out.

The letter "n" is missing from the word "then": "the do"

The IN operator is being used incorrectly. A single value can precede the word IN, with a list of values following the word IN.

It is unlikely you want to include parentheses within your list of values, as would happen in your program.

Also note (this could change the way you structure your program), following the IN operator you are allowed to use an array reference

Good luck.

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 16:22:45 GMT

@PaigeMiller @Astounding I can't copy code of the environment. So typed up the code and had typos here is the correct code:

%let testA=("A1" "A2" "A3");
%let testB=("B1" "B2" "B3");


data NEED;
set HAVE;

%macro var_list;

%let var_list = TESTA TESTB;
%local i var;
%do i=1 %to %sysfunc(countw(&var_list.));
%let var = %scan(&var_list., &i.);

array cond {20} VAR_1-VAR_20;
do i=1 to dim (cond);
do j=1 to countw('&&&var..', ',');
if (cond {i} in &&&var..) then do;
&var.=1;
end;
end;
end;

%end;
%mend;
%var_list;

run;

I get the following error: ERROR 124-185: The variable cond has already been defined

Re: Macro within Macro

PaigeMiller — Sat, 18 Jan 2025 16:53:19 GMT

Okay, problem #1: Do not define a macro beginning with %MACRO and ending with %MEND inside a data step. Define the macro outside (before) the data step and then call it within the data step.

Problem #2, and agreeing with @Astounding , you absolutely (as in MUST, not optional) get the code to work properly in one situation, without macros and without macro variables. If the code doesn't do what you want without macros and without macro variables, then you will NEVER be able to get it to work with macros and with macro variables. So do that, if you are having trouble doing this, show us the code you tried that doesn't work properly WITHOUT macros and WITHOUT macro variables. And if you get it to work without macros and without macro variables, then we can help you turn it into a macro.

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 17:02:39 GMT

@PaigeMiller why do you have to start and end the macro outside of data step?You mean this:

%macro var_list;

data need;
set have;
run;

%mend
&var_list;

Re: Macro within Macro

Kurt_Bremser — Sat, 18 Jan 2025 17:14:33 GMT

Your definition of cond is inside the %DO loop, so the ARRAY statement will be repeatedly created, causing the ERROR.

But that's just the obvious thing. You MUST start your macro development with working non-macro code for a single instance. Then decide what must be repeated and therefore created dynamically, and create the macro for that.

Re: Macro within Macro

PaigeMiller — Sat, 18 Jan 2025 17:20:36 GMT

I said "Define the macro outside (before) the data step and then call it within the data step." So, %MACRO all the way down to %MEND is before the data step.

Why? Because you have to define a macro (starting with %MACRO and then some code and ending with %MEND) before you can call it. Then you can do this:

data need;
    set have;
    %var_list
run;

In this way, the macro code and the data step code will work together properly, if the macro %VAR_LIST is written properly. You can't combine SAS tools (like macros and data steps) willy-nilly without regards to how they work, and expect them to work. What does happen when you execute macro code? It replaces the macro with the code inside the macro, and you CANNOT do things that are not allowed in a data step, here is an example of something that is not allowed in a data step and so won't work, even if it is called by a macro.

data want;
    set have;
    twas brillig = and the slithy toves;
run;

This won't work because you cannot have spaces between variables named TWAS BRILLIG on the left side of the equal sign, you can't even have two variable names on the left side; and similarly the space on the right side will cause an error.

But again, I consider it mandatory that you write code that works and does what you want without macros and without macro variables for one instance of this problem you are trying to solve. MANDATORY. You will never make any progress otherwise. Now three people have told you to do this, I expect you will give that a try rather than continuing to attempt to write macros without that step.

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 19:15:55 GMT

I figured it out. Below it the code that works.

%let testA=("A1" "A2" "A3");
%let testB=("B1" "B2" "B3");


data NEED;
set HAVE;

%macro var_list;

%let var_list = TESTA TESTB;
%local i var;
%do i=1 %to %sysfunc(countw(&var_list.));
%let var = %scan(&var_list., &i.);

array cond_&var. {20} VAR_1-VAR_20;
do i=1 to dim (cond_&var.);
do j=1 to countw('&&&var..', ',');
if (cond_&var.{i} in &&&var..) then do;
&var.=1;
end;
end;
end;

%end;
%mend;
%var_list;

run;

The code works even if you start the %macro inside the data step. So I'm not sure about your point @PaigeMiller. Could you please provide an example when it matters when you start and end the macro and maybe also the code. I'm still confused where you would put

%macro var_list;

%end;
%mend;
%var_list;

Re: Macro within Macro

PaigeMiller — Sat, 18 Jan 2025 21:00:35 GMT

Off the top of my head, I don't have an example of why you shouldn't begin a macro definition inside a data step. If I think of one I will let you know, or maybe the others can jump in with an example. And I never said it can't work, I said (or implied) that it is considered a poor practice and should be avoided.

It seems that you have learned all the wrong lessons here. You appear to have learned that either through brute force or sheer luck or both, you can make this macro work. This is not a good lesson to carry forward, and we have tried to steer you into a better approach, which requires neither brute force nor sheer luck. There's a reason why people like @Kurt_Bremser and @Astounding (and me) recommend a different approach, and this is because it is less effort and more likely to succeed.

So, it's not that your way will never work; it's that it is inefficient and has a higher probability of failure.

Re: Macro within Macro

Tom — Sat, 18 Jan 2025 21:04:44 GMT

The main reason to define the macro BEFORE the data step is to avoid confusing yourself.

The macro processor interprets the text of your program and the results are passed onto to the actual SAS language processor to operate. By placing the macro definition inside the DATE step it gives the programmer the false impression that the macro is compiled while the data step is running.

The other reason is it make the code easier to read.

So first let's move the macro definition to the first thing in your program.

%macro var_list;
%local i var varlist;
%let var_list = TESTA TESTB;
%do i=1 %to %sysfunc(countw(&var_list.));
  %let var = %scan(&var_list., &i.);
array cond_&var. {20} VAR_1-VAR_20;
do i=1 to dim (cond_&var.);
  do j=1 to countw('&&&var..', ',');
    if (cond_&var.{i} in &&&var..) then do;
      &var.=1;
    end;
  end;
end;
%end;
%mend ;

%let testA=("A1" "A2" "A3");
%let testB=("B1" "B2" "B3");

data NEED;
  set HAVE;
%var_list;
run;

Notice how I added VAR_LIST to your list of LOCAL macro variables that the macro is defining and using while it executes.

Now let's try to understand what the macro code is doing. One thing that looks wrong is the use of macro variable references inside of a string quoted with single quotes. Such strings are ignored by the macro processor. So this DO loop

do j=1 to countw('&&&var..', ',');

will iterate only one time since there are no commas in the string passed as the first argument to the COUNTW() function.

And why are you defining multiple arrays that contain the same set of variables?

MPRINT(VAR_LIST): array cond_TESTA {20} VAR_1-VAR_20;
...
MPRINT(VAR_LIST): array cond_TESTB {20} VAR_1-VAR_20;

Can you explain in words what you are trying to do?

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 21:06:33 GMT

@PaigeMiller oh I did use the advice of you, @Kurt_Bremser, and @Astounding gave me. I removed the macro and wrote the code for two cases without the macro. This is how I realized what I was missing.

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 21:17:52 GMT

@Tom I have 20 variables that contain different strings. I need to create a lot of different indicator variables depending on combinations of strings in those 20 variables. For instance if any of the 20 variables contain the strings A1, A2, and A3 the indicator testA should equal to 1 and 0 otherwise. If any of the 20 variables contain the strings B1, B2, and B3 the indicator testB should equal to 1 and 0 otherwise.

Re: Macro within Macro

Tom — Sat, 18 Jan 2025 21:28:52 GMT

So you want to do something like this?

data have;
  row+1;
  input (var_1-var_4) ($);
cards;
A1 C1 .  .
D1 C2 B3 .
. . . .
;

data want;
  set have;
  array var_[4];
  do i=1 to dim(var_) until(testA);
    testA = var_[i] in ('A1' 'A2' 'A3');
  end;
  do i=1 to dim(var_) until(testB);
    testB = var_[i] in ('B1' 'B2' 'B3');
  end;
  drop i;
run;

Where the only part that varies are the DO loops at the end.

You could make a macro that just generates the DO loops.

%macro dx_test(names,codelists);
%local i name codelist ;
%do i=1 %to %sysfunc(countw(&names,%str( )));
  %let name=%scan(&names,&i,%str( ));
  %let codelist=%scan(&codelist,&i,|);
do i=1 to dim(var_) until(&name);
  &name = var_[i] in (&codelist);
end;
%end;
%mend;

Then call it like this:

data want;
  set have;
  array var_[4];
%dx_test(names=testA testB,codelists='A1' 'A2' 'A3'|'B1' 'B2' 'B3')
  drop i;
run;

But does that really save you any typing or make the code easier to follow?

Re: Macro within Macro

Tom — Sat, 18 Jan 2025 22:43:01 GMT

Probably even better to make a really simple macro:

%macro dx_test(name,codelist);
do i=1 to dim(var_) until(&name);
  &name = var_[i] in (&codelist);
end;
%mend;

And just call it multiple times.

data want;
  set have;
  array var_[4];
%dx_test(testA,'A1' 'A2' 'A3')
%dx_test(testB,'B1' 'B2' 'B3')
  drop i;
run;

Re: Macro within Macro

trevand — Sat, 18 Jan 2025 23:36:21 GMT

If I use the last suggestion I would have to spell out 20 times or so the different indicators that I want to create. That's why I wanted to use the var_list macro.

Can you please explain why

do j=1 to countw('&&&var..', ',');

will only iterate until the first string? In the example that you provided B3 is still found if use the code above.

Re: Macro within Macro

Tom — Sun, 19 Jan 2025 00:04:46 GMT

Try it yourself and see.

 1          data _null_;
 2            do j=1 to countw('&&&var..', ',');
 3              put j=1;
 4            end;
 5          run;
 
 j=1
 NOTE: DATA statement used (Total process time):
       real time           0.00 seconds
       cpu time            0.00 seconds

Try this to see WHY.

 1          data _null_;
 2            string = '&&&var..';
 3            put string=;
 4          run;
 
 string=&&&var..
 NOTE: DATA statement used (Total process time):
       real time           0.00 seconds
       cpu time            0.00 seconds

The macro processor IGNORES strings made using single quote characters instead of double quote characters.

You have to type the same information either way.

Better to have the lists in data

data dxgroups;
  infile datalines truncover;
  length varname $32 num 8 code $10 disease $50;
  input varname  disease $50. ;
  do codenum=1 by 1 until(missing(code));
     input code @ ;
     if not missing(code) then output;
  end;
cards;
hpb Hypertension
A1 A2 A3 A4
db Diabetes
B1 B2 B3
;

and use the data to generate the code.

For example you could use it to generate calls to %DXTEST() macro I showed.

filename code temp;
data _null_;
  file code;
  set dxgroups;
  by varname notsorted;
  if first.varname then put '%dxtest(' varname ',' @;
  put code :$quote. @;
  if last.varname then put ')';
run;

And then you can use %INCLUDE to execute that generated code where you want.

data want;
  set have;
  array var_[20] ;
%include code / source2;
  drop i;
run;

Re: Macro within Macro

trevand — Sun, 19 Jan 2025 00:28:04 GMT

But this should be okay then?

%let testA=("A1" "A2" "A3");
%let testB=("B1" "B2" "B3");


data NEED;
set HAVE;

array cond_testA {20} VAR_1-VAR_20;
do i=1 to dim (cond_testA);
do j=1 to countw('&testA.', ',');
if (cond_testA {i} in &testA.) then do;
testA=1;
end;
end;
end;

array cond_testB {20} VAR_1-VAR_20;
do i=1 to dim (cond_testB);
do j=1 to countw('&testB.', ',');
if (cond_testB {i} in &testB.) then do;
testB=1;
end;
end;
end;


run;

The problem only arises with &&&var..? Sorry I'm still confused. I'm coming from stata where it's super easy to loop through strings.

Re: Macro within Macro

Tom — Sun, 19 Jan 2025 01:18:36 GMT

There is a huge difference to SAS macro processor between

do j=1 to countw('&testB.', ',');

and

do j=1 to countw("&testB.", ',');

And even if you changed to the second then SAS code that the macro processor would pass onto SAS to execute would look like:

do j=1 to countw("("B1" "B2" "B3")", ',');
if (cond_testB {i} in ("B1" "B2" "B3")) then do;
testB=1;
end;

Which not only is invalid syntax it does not make any sense.

Did you mean to do something like this?

testB=0;
do i=1 to dim(cond_testB);
  if (cond_testB[i] in &testB.) then testB=1;
end;

If so then that is what the DO loops I showed are doing,

do i=1 to dim(cond_testB) until(testB);
  testB= (cond_testB[i] in &testB.) ;
end;

but they stop looping as soon as there is a match.

So your code worked because the two mistakes (miss use of macro code and the extra unneeded DO loop) cancel each other out.

Note also that [ and ] are easier to type and easier to distinguish from ( and ) in the code than { and }.

Re: Macro within Macro

trevand — Sun, 19 Jan 2025 01:37:13 GMT

data have;
  row+1;
  input (var_1-var_4) ($);
cards;
A1 C1 .  .
D1 C2 B3 .
. . . .
;

data want;
  set have;
  array var_[4];
  do i=1 to dim(var_) until(testA);
    testA = var_[i] in ('A1' 'A2' 'A3');
  end;
  do i=1 to dim(var_) until(testB);
    testB = var_[i] in ('B1' 'B2' 'B3');
  end;
  drop i;
run;

I will just use this code as you suggested. One question though. Why do you need until(testA)?