topic Re: Concordance Correlation Coefficient in New SAS User

Concordance Correlation Coefficient

Luke01 — Sat, 07 Dec 2019 05:56:15 GMT

Hi community,

Im having trouble trying to calculate Concordance Correlation Coefficient. How can i do this?

I am aware of: https://newonlinecourses.science.psu.edu/stat509/node/161/

but it seems to have old procedures that are not relevent for more recent SAS versions.

thanks in advance.

Re: Concordance Correlation Coefficient

Ksharp — Sat, 07 Dec 2019 10:44:24 GMT

Did you try the FOUR kind of correlation coefficient in PROC CORR.

proc corr data=sashelp.class kendall;
var weight height;
run;

Re: Concordance Correlation Coefficient

PaigeMiller — Sat, 07 Dec 2019 11:51:59 GMT

@Luke01 look at the link I gave you in your other thread ... it was meant as a reference for you to refer back to as needed, not as a one time thing.

Re: Concordance Correlation Coefficient

Luke01 — Sat, 07 Dec 2019 12:22:05 GMT

yes it refers to kendels, i am after Lins.

Re: Concordance Correlation Coefficient

Luke01 — Sat, 07 Dec 2019 12:27:39 GMT

I am after lin's concordance correlation coefficient, not the same as correlation in terms of pearson's etc.

ie y=x.

Re: Concordance Correlation Coefficient

FreelanceReinh — Sat, 07 Dec 2019 13:16:23 GMT

Hi @Luke01,

You can get the all the terms used in the formula from PROC CORR: Just use the COV and OUTP= options. The rest is a simple calculation, e.g., in a DATA step.

Example (assuming a dataset HAVE with numeric variables X and Y with only non-missing values):

proc corr data=have cov outp=stats noprint;
var x y;
run;

data want(keep=rc);
do until(last);
  set stats end=last;
  sxx+(_type_='COV')*(upcase(_name_)='X')*x;
  syy+(_type_='COV')*(upcase(_name_)='Y')*y;
  sxy+(_type_='COV')*(upcase(_name_)='X')*y;
  mx +(_type_='MEAN')*x;
  my +(_type_='MEAN')*y;
  n  +(_type_='N')*x;
end;
rc=2*sxy/(sxx+syy+(mx-my)**2);
run;

RC is the concordance correlation coefficient as per the link you provided.

Re: Concordance Correlation Coefficient

Luke01 — Sat, 07 Dec 2019 22:59:22 GMT

Sorry for my ignorance im new to SAS and coding etc.

But what does sxx, my etc refer to?

Do i need to sub my x and y variables in?

Same for _name_

Just as I am getting 0 for rc which isnt right. Below is an example of what I did.

proc corr data=HAVE cov outp=stats noprint;
var x_variable y_variable;
run;

data want(keep=rc);
do until(last);
  set stats end=last;
  sxx+(_type_='COV')*(upcase(_name_)='X')*x_variable;
  syy+(_type_='COV')*(upcase(_name_)='Y')*y_variable;
  sxy+(_type_='COV')*(upcase(_name_)='X')*y_variable;
  mx +(_type_='MEAN')*x_variable;
  my +(_type_='MEAN')*y_variable;
  n  +(_type_='N')*x_variable;
end;
rc=2*sxy/(sxx+syy+(mx-my)*2);
run;

thank you

Re: Concordance Correlation Coefficient

FreelanceReinh — Sun, 08 Dec 2019 00:06:24 GMT

@Luke01 wrote:

But what does sxx, my etc refer to?

These are just arbitrary variable names. I used names reflecting the terms in the formula (e.g. sxx for S_XX ). These variables are not kept in the output dataset (see the KEEP= option in the DATA statement -- but you may change that if you like), so their names don't really matter.

So i need to sub my x and y variables in?

You need to replace the dataset name have in the PROC CORR step with the name of your dataset. If the variables in your dataset for which you want to compute the concordance correlation coefficient are not named x and y, you would ideally use a RENAME= dataset option in the PROC CORR step. So, using the example program (see the link on the web page you linked to in your initial post) the PROC CORR step would read:

proc corr data=dice_baseline(rename=(cort_auc1=x cort_auc2=y)) cov outp=stats noprint;
var x y;
run;

(where stats is an arbitrary dataset name -- in case of a name conflict just use a different name).

Alternatively, let PROC CORR work with the original names and then replace "x" and "y" by these names in the DATA step in nine places, not only six as you did in your code: The character constants 'X' and 'Y' must also be replaced by 'X_VARIABLE' and 'Y_VARIABLE' (upper case is mandatory), respectively.

The DATA step reads the output dataset stats produced by PROC CORR, computes the concordance correlation coefficient and stores it in a numeric variable named rc in a dataset want containing only one record. (Both rc and want are arbitrary names.)

Same for _name_

The output dataset from PROC CORR contains character variables _type_ and _name_ (these are default names) which contain names of statistics and variables, respectively, and are used in the DATA step. I wrote the DATA step looking at PROC PRINT output of dataset stats:

proc print data=stats;
run;

Re: Concordance Correlation Coefficient

tka726 — Fri, 17 Jan 2020 16:31:51 GMT

This worked perfectly for me, thank you!! Can the confidence interval for the CCC be obtained from this output as well?

Re: Concordance Correlation Coefficient

FreelanceReinh — Fri, 17 Jan 2020 22:52:36 GMT

Hello @tka726,

Yes, in principle this is possible (e.g., the Pearson correlation coefficient from the PROC CORR output dataset stats would be involved in the calculation; also the TANH and ARTANH functions could be applied to simplify some terms). However, I found a couple of discrepancies between the formula used in the IML code from the psu.edu website linked by @Luke01 and a formula I saw elsewhere -- whereas the formulas for the point estimate were equivalent. Therefore, I'm hesitant to publish SAS code for the confidence interval, unless you provide a (link to a) reliable formula for it in mathematical notation like the formula for the point estimate on the psu.edu website.

Re: Concordance Correlation Coefficient

vedatoguz — Wed, 11 Dec 2024 14:31:08 GMT

Hi,

I have about 40 variables to calculate the CCC and I am having hard time to create a macro. Especially for the portion of upcase(_name_=)

Would you be able to provide me a macro code?

Re: Concordance Correlation Coefficient

FreelanceReinh — Wed, 11 Dec 2024 17:12:14 GMT

Hi @vedatoguz and welcome to the SAS Support Communities!

Yes, I think I can help you with the macro code, but only in the next few days -- sorry for the delay -- and only for the CCC itself (not: confidence interval), i.e., based on the code I proposed to @Luke01 five years ago.

Hint for your future questions: In this forum (unlike some others) it is always better to start your own thread than to add a new request to someone else's old thread.

Re: Concordance Correlation Coefficient

FreelanceReinh — Thu, 12 Dec 2024 15:46:39 GMT

Thinking more about your request, I realized that a non-macro solution is likely more efficient than a macro. Note that all the statistics needed for the calculation of the concordance correlation coefficients (CCCs) are contained in the output of PROC CORR, applied to the list of your about 40 variables. So, the CCCs can be computed in a DATA step going through the list of all ordered pairs of variables. This list, in turn, can be created from the PROC CORR output dataset by PROC TRANSPOSE.

Here is an example using the SAS-supplied dataset SASHELP.JUNKMAIL, from which I took an arbitrary list of 40 numeric variables just to demonstrate that the code works. The final dataset WANT contains comb(40,2)=780 observations, one for each ordered pair of variables.

/* Compute mean values and empirical (co)variances */

proc corr data=sashelp.junkmail cov outp=stats noprint /* vardef=n */;
var make--direct; /* This variable list contains 40 (numeric) variables. */
run;

/* Create a "long" dataset from the empirical covariance matrix, avoiding redundant values of the statistic (_s) */

proc transpose data=stats(rename=(_name_=_var1)) name=_var2 out=covlist(where=(_var1<=_var2) rename=(col1=_s));
where _type_='COV';
by _var1 notsorted;
run;

/* Create a "long" dataset containing the mean values from the PROC CORR output dataset */

proc transpose data=stats(drop=_name_) name=_var1 out=means(rename=(col1=_s));
where _type_='MEAN';
run;

/* Compute the concordance correlation coefficients (_rc) as in the code posted on Dec 7, 2019 */

data want(keep=_var1 _var2 _rc);
set covlist(where=(_var1<_var2));
if _n_=1 then do;
  dcl hash _m(dataset:'means');
  _m.definekey('_var1');
  _m.definedata('_s');
  _m.definedone();
  dcl hash _v(dataset:'covlist(where=(_var1=_var2))');
  _v.definekey('_var1');
  _v.definedata('_s');
  _v.definedone();
end;
_sxy=_s;
_sxx=ifn(_v.find(),.,_s);
_syy=ifn(_v.find(key:_var2),.,_s);
_mx =ifn(_m.find(),.,_s);
_my =ifn(_m.find(key:_var2),.,_s);
_rc=2*_sxy/(_sxx+_syy+(_mx-_my)**2);
run;

/* Optional: Sort the resulting dataset alphabetically */

proc sort data=want;
by _var1 _var2;
run;

By using the VARDEF option of the PROC CORR statement (commented out in the code above) you can easily switch between the slightly different implementations of the CCC obtained with VARDEF=DF (the default) and VARDEF=N, which are mentioned in the Wikipedia article Concordance correlation coefficient (at the end of the section headed "Definition").

Re: Concordance Correlation Coefficient

vedatoguz — Fri, 13 Dec 2024 14:22:47 GMT

Thank you very much. It is very helpful.