topic Re: Question about input statement and resultant log errors in New SAS User

Question about input statement and resultant log errors

sasgorilla — Wed, 16 Oct 2024 21:32:46 GMT

I have character variables that have numeric values, such as height and weight. To recode these as numeric, I made a new variable using the 'input' such as below.

weightnew = input(weightold, 8.);

Functionally this works, but it also produces an error wherever there is a missing value for weightold.

NOTE: Invalid argument to function INPUT at line 10516 column 10.
WARNING: Limit set by ERRORS= option reached.  Further errors of this type will not be printed.

This ultimately doesn't appear to matter as each of those missing character values becomes recoded as a missing numeric value, but the sight of all those errors in the log makes me worry something is wrong.

Is there a better way to change weightold (character) to weightnew (numeric) than using the input statement?

Secondly, should I be bothered by the error log looking the way it does, or if it is doing what I want should I just ignore?

Thanks.

Re: Question about input statement and resultant log errors

Cynthia_sas — Thu, 17 Oct 2024 01:22:10 GMT

Hi:

I'd go back and look at your code more carefully. If your data is as you describe, then you should not have the INPUT function NOTE that you received. Are you sure your weights are standard numbers? I don't observe the same behavior with a test data table that has a character value for WEIGHTOLD and gets converted to a numeric variable WEIGHTNEW:

But you can force the INPUT note if your character string is not composed of standard numeric values. In the example below, the period is the thousands separator and the comma is the decimal separator, so I can see the NOTE in the log with a simple INFORMAT and I get rid of the NOTE using the COMMAX informat.

Cynthia

Re: Question about input statement and resultant log errors

ballardw — Thu, 17 Oct 2024 02:03:29 GMT

When there are known issues and you just want the log not to show invalid data you can use a modifier in the Input function:

data example;
   input weightold $;
   weightnew = input(weightold, ?? 8.);
datalines;
1.23
33lb
45.8
abc
;

Note the two question marks. They modify the Input to not display invalid data.

I would suggest not using this option unless you very sure of the reasons why you have values that can't be made numeric such as text like N/A entered in a source.

Re: Question about input statement and resultant log errors

Patrick — Thu, 17 Oct 2024 03:32:03 GMT

If you've got known strings like n/a that you want to convert to missings but also want to stay on the safe side and not just suppress any errors or warnings with the ?? modifier then you could also create your own informat using code similar to below.

proc format;
  invalue char2num
    'n/a' = .
    other = [best32.]
    ;
run;

data demo_1;
  infile datalines truncover;
  input charvar $;
  numvar_1=input(charvar,char2num32.);
  datalines;
11
2
n/a
4
;

data demo_2;
  infile datalines truncover;
  input charvar $;
  numvar_1=input(charvar,char2num32.);
  datalines;
11
2
n/a
4
xxx
;

Re: Question about input statement and resultant log errors

Kurt_Bremser — Thu, 17 Oct 2024 06:58:01 GMT

Maxim 3: Know Your Data.

Your log should also have a listing of variable values when an "invalid" NOTE is issued.

Your variable weightold contains character data which cannot be converted by using the 8. informat.

Please show us those values.

Re: Question about input statement and resultant log errors

Kurt_Bremser — Thu, 17 Oct 2024 10:28:43 GMT

BTW your subject line is not correct. Your issue is not with the INPUT statement, but with the INPUT() function.

Re: Question about input statement and resultant log errors

Astounding — Thu, 17 Oct 2024 08:10:28 GMT

Here's a way to explore the data, to see which values are causing a problem:

proc freq data=have;
   tables weight;
   where input(weight, ??8.) = .;
run;

It might be that all the trouble-makers are "." or there might be a more troublesome situation such as substituting "O" for "0" some of the time.

Re: Question about input statement and resultant log errors

sasgorilla — Thu, 17 Oct 2024 10:51:28 GMT

Thankyou for your help, everyone! I accepted this as the solution since it helped me catch and clean few values that were contributing to the errors.

One correction: your provided code would not run unless I eliminated one of the '?'. The code below is what worked for me.

proc freq data=have;
   tables weight;
   where input(weight, ?8.) = .;
run;

Re: Question about input statement and resultant log errors

Tom — Thu, 17 Oct 2024 12:42:55 GMT

Yes. The WHERE statement is processed like an SQL statement. And in that setting the functionality implied by the ?? modifier does not exist.

Also are you positive the character variable has a maximum length of only 8? If not then you use of a width of 8 on the informat will ignore the end of the string. Unless there is some reason you want it to ignore the ends of the string use the maximum width that the informat supports, which is 32. The INPUT() function does not care if the width of the informat specification is larger than the length of the string being read.