topic Re: ODS Powerpoint - Forcing proc sql label text to stay on same line in New SAS User

ODS Powerpoint - Forcing proc sql label text to stay on same line

sasser27 — Wed, 18 Sep 2024 04:06:11 GMT

Simple question I presume - For my PPT export, part of my code has a slide where a few counts are outputted into simple boxes with a label. However, the label text keeps shifting each word onto a separate line so I end up with 3+ lines for a label. I've tried options/methods that are used for ODS HTML including page size, gridded, etc. but to no avail. Any solution for this or is it better to use an alternate method (e.g. proc report, proc tabulate, etc.)?

Here's a sample of the code:

ods powerpoint file = customers;
options nodate papersize=(10in. 7.5in);
ods escapechar="^"

ods powerpoint layout=titleandcontent nogtitle style=sapphire;

proc sql;
select count(distinct ID) as Leads label="Leads for August" format=comma12.
from leads_august24;
select count(distinct ID) as Customers label="Customers for August" format=comma12.
from sales_august24;
select sum(amount) as Sales label="Sales for August" format=comma12.
from sales_august24;
quit;

ods powerpoint close;

Re: ODS Powerpoint - Forcing proc sql label text to stay on same line

Ksharp — Wed, 18 Sep 2024 06:34:26 GMT

You could switch it into PROC REPORT which have more control in ODS.

ods powerpoint file ='c:\temp\temp.pptx';
options nodate;
ods escapechar="^";
data sales_august24;
 do id=1 to 100;
  amount=rand('uniform');output;
 end;
run;
ods powerpoint layout=titleandcontent nogtitle style=sapphire;

proc sql noprint;
create table want1 as
select count(distinct ID) as Leads label="Leads for August" format=comma12.
from sales_august24;
create table want2 as
select count(distinct ID) as Customers label="Customers for August" format=comma12.
from sales_august24;
create table want3 as
select sum(amount) as Sales label="Sales for August" format=comma12.
from sales_august24;
quit;
proc report data=want1 nowd ;
define _all_/display style(column)={cellwidth=5cm};
run;
proc report data=want2 nowd ;
define _all_/display style(column)={cellwidth=5cm};
run;
proc report data=want3 nowd ;
define _all_/display style(column)={cellwidth=5cm};
run;

ods powerpoint close;