topic Re: ERROR 79-322: Expecting a CONTENTS in New SAS User

ERROR 79-322: Expecting a CONTENTS

kcvaldez98 — Mon, 20 Nov 2023 16:04:26 GMT

Hi SAS coders,

I am trying to do a PROC REPORT and ran into this error: " ERROR 79-322: Expecting a CONTENTS."

My code is

PROC REPORT DATA = HYPANL.HYPANALYSIS1_20231116 SPLIT = '/';

COLUMNRaceCd N SBP DBP;

DEFINETxNm/ 'Race Code';

DEFINEN/ GROUP;

DEFINESBP/ ANALYSIS MEAN FORMAT = 4.1 'MEAN';

DEFINESBP/ STD = 'STD';

DEFINEDBP/ ANALYSIS MEAN FORMAT = 4.1 'MEAN';

DEFINE DBP / STD = 'STD';

RUN;

I attached a ss to show where it says the error.

I don't know what this error means.

Re: ERROR 79-322: Expecting a CONTENTS

Kurt_Bremser — Mon, 20 Nov 2023 16:28:29 GMT

As posted, your code can't work, as yo have no blanks separating the statements (COLUMN or DEFINE) from the variable names.

Next, you have a variable in COLUMN for which no DEFINE exists, and a DEFINE for a variable not included in COLUMN.

Finally, the only options in a DEFINE statement which have an equal sign are COLOR and CONTENTS. Labels are given as quoted strings without an equal sign. To display multiple statistics for a single variable, define the statistics in the COLUMN statement.

proc report data=HYPANL.HYPANALYSIS1_20231116 split='/';
column TxNm N SBP,(mean std) DBP,(mean std);
define TxNm / 'Race Code';
define N / group;
define SBP / analysis;
define DBP / analysis;
run;

For detailed help, post example data in a DATA step with DATALINES; and the expected result from this.

Re: ERROR 79-322: Expecting a CONTENTS

kcvaldez98 — Mon, 20 Nov 2023 16:41:53 GMT

Thank you so much!

Some data and expected results is this:

DATA =

RaceCd, SBP, DBP

161

160

168

176

159

My outcome should look like this minus the actual numbers since I am only providing you a fraction of the dataset that I am working with.

Thank you, again!

Re: ERROR 79-322: Expecting a CONTENTS

Kurt_Bremser — Tue, 21 Nov 2023 13:56:20 GMT

See this:

proc format;
value $rcd
  "B" = "Black"
  "O" = "Other"
  "W" = "White"
;
run;

data have;
input RaceCd :$1. SBP DBP;
label
  RaceCd = "Race Code"
  SBP = "Systolic"
  DBP  = "Diastolic"
;
format RaceCd $rcd.;
datalines; 
B 161 65
B 160 78
O 168 70
W 176 73
W 159 65
;

proc report data=have;
column RaceCd n ("Average Presures" SBP,(mean std) DBP,(mean std));
define RaceCd / group;
define N / "N";
define SBP / analysis;
define DBP / analysis;
rbreak after / summarize;
run;