topic Re: Extracting a certain text between comma and period in a Character variable. in New SAS User

Extracting a certain text between comma and period in a Character variable.

Rahim_221 — Thu, 17 Aug 2023 22:30:45 GMT

Hi,

I have a character variable named "Title and Authors" that contains a long text and I want to extract a certain text which is last Author name that lies between comma and period as shown in RED the example below:

Title and Authors

1- Minervina AA, Pogorelyy MV, Kirk AM, Crawford JC, Allen EK, Chou CH, Mettelman RC, Allison KJ, Lin CY, Brice DC, Zhu X, Vegesana K, Wu G, Trivedi S, Kottapalli P, Darnell D, McNeely S, Olsen SR, Schultz-Cherry S, McGargill MA, Wolf J, Thomas PG. SARS-CoV-2 antigen exposure history shapes phenotypes and specificity of memory CD8(+) T cells.

2- Bauler M, Roberts JK, Wu CC, Fan B, Ferrara F, Yip BH, Diao S, Kim YI, Moore J, Zhou S, Wielgosz MM, Ryu B, Throm RE. Production of lentiviral vectors using suspension cells grown in serum-free media.

Thanks

Re: Extracting a certain text between comma and period in a Character variable.

Patrick — Thu, 17 Aug 2023 22:52:14 GMT

Below should work if the desired substring is always right after the 2nd period in your source string.

data null;
  string='2- Bauler M, Roberts JK, Wu CC, Fan B, Ferrara F, Yip BH, Diao S, Kim YI, Moore J, Zhou S, Wielgosz MM, Ryu B, Throm RE. Production of lentiviral vectors using suspension cells grown in serum-free media.';
  length lastAuthor $40 listAuthors $200;
  listAuthors=scan(string,-2,'.');
  lastAuthor=scan(listAuthors,-1,',');
  put lastAuthor=;
run;

Re: Extracting a certain text between comma and period in a Character variable.

Rahim_221 — Thu, 17 Aug 2023 22:58:29 GMT

Thank you. The code you provided worked on only the second observation, however I have about 1900 rows/observations that I want to extract the last author's name from. Is there a way to make this code work on all observations?

Re: Extracting a certain text between comma and period in a Character variable.

Patrick — Thu, 17 Aug 2023 23:14:39 GMT

The length for listAuthors was too short for your first sample. If you increase the length then the code as posted works for both rows of your sample data.

If it's going to work for all your data depends on the assumption that the text after the Authors doesn't contain some "embedded" period.

Re: Extracting a certain text between comma and period in a Character variable.

Tom — Fri, 18 Aug 2023 00:14:21 GMT

Since the style seems to be to not have periods for author initials it looks pretty simple to find the last author.

data have;
  infile cards truncover;
  input line $500.;
cards4;
1- Minervina AA, Pogorelyy MV, Kirk AM, Crawford JC, Allen EK, Chou CH, Mettelman RC, Allison KJ, Lin CY, Brice DC, Zhu X, Vegesana K, Wu G, Trivedi S, Kottapalli P, Darnell D, McNeely S, Olsen SR, Schultz-Cherry S, McGargill MA, Wolf J, Thomas PG. SARS-CoV-2 antigen exposure history shapes phenotypes and specificity of memory CD8(+) T cells.
2- Bauler M, Roberts JK, Wu CC, Fan B, Ferrara F, Yip BH, Diao S, Kim YI, Moore J, Zhou S, Wielgosz MM, Ryu B, Throm RE. Production of lentiviral vectors using suspension cells grown in serum-free media.
;;;;

data want;
  length author $80;
  set have;
  author=left(scan(scan(line,1,'.'),-1,','));
run;

Re: Extracting a certain text between comma and period in a Character variable.

Rahim_221 — Thu, 17 Aug 2023 23:28:22 GMT

Thank you so much. It worked.