topic Re: Set same range for heatmap on BY statement in New SAS User

Set same range for heatmap on BY statement

linlin87 — Mon, 13 Feb 2023 21:32:48 GMT

Hi SAS community

I have heatmap of values (0-1). I have on a BY variable ("disease"). I want to do and I can't work out how:

Fix the color range to be 0-1. Currently it is using the minimum value in my dataset to be white, maximum to be black. I want white=0 and Black=1.
Fix the color range across BY groups. Obviously with 1. above, when I do BY statement, it changes color map across the BY groups because it not fixed at 1 and 0.
I want 'color legend' for all plots to display the full range: 0 (white) to 1 (black)

Any help would be appreciate

proc template;
  define statgraph corrHeatmap;
   dynamic _Title;
    begingraph;
      entrytitle _Title;
      rangeattrmap name='map';
      endrangeattrmap;
      rangeattrvar var=r attrvar=r attrmap='map';
      layout overlay / 
        xaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear')) 
        yaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear'));
        heatmapparm x = x y = y colorresponse = rsquare / 
          xbinaxis=true ybinaxis=true
          name = "heatmap" display=all colormodel=(white black);
        continuouslegend "heatmap" / 
          orient = vertical location = outside title="Pearson Correlation";
      endlayout;
    endgraph;
  end;
run;

proc sort data=fit;
by disease;
run;
 
proc sgrender data=fit template=corrHeatmap;
	by disease;
	dynamic _title="Correlation matrix";
run;

Re: Set same range for heatmap on BY statement

Rick_SAS — Mon, 13 Feb 2023 14:20:45 GMT

Two suggestions:
1. Use the RANGE statement inside the RANGEATTRMAP/ENDRANGEATTRMAP block.

2. Add some fake data to each BY group to force the continuous legend to always display tick marks at 0 and 1. There might be a better way to do this. Maybe @DanH_sas knows a better way:


proc template;
  define statgraph corrHeatmap;
   dynamic _Title;
    begingraph;
      entrytitle _Title;
      rangeattrmap name='map';
      range 0-1;  /* set range to [0,1] */
      endrangeattrmap;
      rangeattrvar var=r attrvar=r attrmap='map';
      layout overlay / 
        xaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear')) 
        yaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear'));
        heatmapparm x = x y = y colorresponse = rsquare / 
          xbinaxis=true ybinaxis=true
          name = "heatmap" display=all colormodel=(white black);
        continuouslegend "heatmap" / 
          orient = vertical location = outside title="Pearson Correlation"
          VALUECOUNTHINT=11;
      endlayout;
    endgraph;
  end;
run;


/* make some example data */
data fit;
do disease = 1 to 2;
   do x = 0 to 3;
      do y = 0 to 3;
         rsquare = (disease + x**2 + y**2) / 25;   /* make range in [0, 1] */
         output;
      end;
   end;
end;
/* check that rsquare is in [0,1] */
proc means data=fit;
class disease;
var rsquare;
run;

proc sort data=fit;
by disease;
run;

/* HACK: insert fake data for rsquare=0 and  rsquare=1 to fool the continuous axis legend */
data Fake;
do disease = 1 to 2;    /* need fake obs for each value of disease */
   rsquare = -1E-3; output;
   rsquare =  1+ 1E-3; output;
end;
run;

data NewFit;
   set Fake Fit;
   by disease;
run;

proc sgrender data=NewFit template=corrHeatmap;
	by disease;
	dynamic _title="Correlation matrix";
run;

Re: Set same range for heatmap on BY statement

DanH_sas — Mon, 13 Feb 2023 20:14:59 GMT

Using the RANGEATTRMAP is the best approach, but you're code needs a little adjustment:

1. The COLORMODEL option needed to be removed from the HEATMAPPARM statement. Instead, the RANGECOLORMODEL needs to be defined on the RANGE statement. Otherwise, there is no binding between the 0-1 range and the white-black color range

2. The RANGEATTRVAR needs to have the RSQUARE variable specified on the VAR option. This option points to the real column in the data. The ATTRVAR option specifies a new reference variable name. This variable (not the RSQUARE) should be used for the COLORRESPONSE on the HEATMAPPARM to create the correct binding.

3. The fake data is not required, so I removed it.

proc template;
  define statgraph corrHeatmap;
   dynamic _Title;
    begingraph;
      entrytitle _Title;
      rangeattrmap name='map';
      range 0.0-1.0 / rangecolormodel=(white black);
      endrangeattrmap;
      rangeattrvar var=rsquare attrvar=r attrmap="map";
      layout overlay /
        xaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear'))
        yaxisopts=(display=(line ticks tickvalues label) label=('Weeks wear'));
        heatmapparm x = x y = y colorresponse = r /
          xbinaxis=true ybinaxis=true
          name = "heatmap" display=all ;
        continuouslegend "heatmap" /
          orient = vertical location = outside title="Pearson Correlation"
          VALUECOUNTHINT=11;
      endlayout;
    endgraph;
  end;
run;

/* make some example data */
data fit;
do disease = 1 to 2;
   do x = 0 to 3;
      do y = 0 to 3;
         rsquare = (disease + x**2 + y**2) / 25;   /* make range in [0, 1] */
         output;
      end;
   end;
end;
/* check that rsquare is in [0,1] */
proc means data=fit;
class disease;
var rsquare;
run;

proc sort data=fit;
by disease;
run;

proc sgrender data=fit template=corrHeatmap;
	by disease;
	dynamic _title="Correlation matrix";
run;

Re: Set same range for heatmap on BY statement

linlin87 — Mon, 13 Feb 2023 21:10:48 GMT

Thank you Rick and Dan