topic Assistance With Geometric Mean in New SAS User

Assistance With Geometric Mean

pauliet987 — Tue, 17 Jan 2023 17:05:52 GMT

Hello,

I need help getting a geometric mean for all values on every date. For instance:

Date: Patients Value

01/02/2023. 1 3

01/02/2023. 2 4

01/05/2023 1 6

01/05/2023 2 7

01/05/2023 3 8

What I want:

Date: Geometric Mean:

01/02/2023 3.46

01/05/2023 6.95

Thank you for any help you are able to provide!

Re: Assistance With Geometric Mean

FreelanceReinh — Tue, 17 Jan 2023 17:59:09 GMT

Hello @pauliet987,

You can use PROC UNIVARIATE:

data have;
input Date :mmddyy. Patients Value;
format Date mmddyy10.;
cards;
01/02/2023 1 3
01/02/2023 2 4
01/05/2023 1 6
01/05/2023 2 7
01/05/2023 3 8
;

proc univariate data=have noprint;
by date;
var value;
output out=want geomean=geom_mean;
run;

proc print data=want;
format geom_mean 8.2;
run;

The BY statement assumes that the input dataset is sorted (or indexed) by date.

Re: Assistance With Geometric Mean

tarheel13 — Sat, 21 Jan 2023 11:57:44 GMT

The other way is with proc means but you have to do take the log of value first like this:

data have2;
   set have;
   if value gt 0 then log_value=log(value);
run;

proc means data=have2 noprint;
   class date;
   var  log_value;
   ways 1;
   output out=stats mean= log_mean;
run;

data stats1;
   set stats;
   geomean=exp(log_mean);
run;