topic Re: Combing several glm plots into one in New SAS User

Combing several glm plots into one

FROA — Tue, 05 Jul 2022 21:06:42 GMT

How can I combine the prediction plot of the three below models into one plot? If you can give me a sample code, I would really appreciate it. Thanks!

proc glm data = Test_data outstat = p_value plots=diagnostics;
model weight = bmi / CLPARM solution;
run;
proc glm data = plasma outstat = p_value plots=diagnostics;
model height = weight / CLPARM solution;
run;
proc glm data = plasma outstat = p_value plots=diagnostics;
model bmi = weight / CLPARM solution;
run;

Re: Combing several glm plots into one

PaigeMiller — Tue, 05 Jul 2022 21:37:37 GMT

Do you mean 3 plots side-by-side fitting on one page? Or 3 plots one above the other fitting on one page? Or some other arrangement fitting on one page?

Please explain.

Also, what is the purpose of modeling WEIGHT=BMI and then later BMI=WEIGHT?

Re: Combing several glm plots into one

FROA — Wed, 06 Jul 2022 15:11:24 GMT

Hi Paige,

Thank you for replying!
The order does not matter, and these are only template models, not the actual models. BMI and Weight could be replaced by any other variable. I just am looking for a sample code to combine different "glm" models' plots into one table/page of plots.

Re: Combing several glm plots into one

PaigeMiller — Wed, 06 Jul 2022 15:22:08 GMT

ODS EXCEL can put many plots onto a single tab, so you can just scroll down in Excel to see them all. Is that what you want?

ods excel file='myfile.xlsx' options(sheet_interval='NONE');
ods excel select diagnosticspanel(persist);
proc glm data = Test_data outstat = p_value plots=diagnostics;
model weight = bmi / CLPARM solution;
run; quit;
proc glm data = plasma outstat = p_value plots=diagnostics;
model height = weight / CLPARM solution;
run; quit;
proc glm data = plasma outstat = p_value plots=diagnostics;
model bmi = weight / CLPARM solution;
run; quit;
ods excel close;

Re: Combing several glm plots into one

Rick_SAS — Thu, 07 Jul 2022 10:36:13 GMT

It sounds like you want to use the ODS LAYOUT GRIDDED statement. See

https://blogs.sas.com/content/sasdummy/2015/11/23/ods-statement-options-to-change/
AND
https://blogs.sas.com/content/graphicallyspeaking/2017/08/14/advanced-ods-controlling-precisely-output-displayed/

Here's how it would look for some sample data:

ods layout gridded columns=2 advance=table;
ods noproctitle;
ods graphics / width=400px height=300px;
ods select FitPlot(persist);

proc glm data = sashelp.heart outstat = p_value plots(MAXPOINTS=NONE)=diagnostics;
model weight = MRW / CLPARM solution;
run;
proc glm data = sashelp.heart outstat = p_value plots(MAXPOINTS=NONE)=diagnostics;
model height = weight / CLPARM solution;
run;
proc glm data = sashelp.heart outstat = p_value plots(MAXPOINTS=NONE)=diagnostics;
model MRW = weight / CLPARM solution;
run;
quit;

ods layout end;

Alternatively, you can write the data to a SAS data set and use PROC SGPANEL to create the graphs yourself.