topic Re: Proc sort issue in New SAS User

Proc sort issue

Dpeter — Mon, 27 Jun 2022 06:27:53 GMT

Please I need assistance with Proc sort.

I sorted a data set by two different variables; SALES and PRODUCT. I want the product variable to be sorted in descending order while the sales variable is sorted in ascending order.

Here is my program:

Proc sort data = sashelp.shoes out = work.sortedshoes;
by sales descending product;

run;

The SALES variable gets sorted in ascending order but the PRODUCT variable was never sorted in descending order.

I also re-instructed as below:

Proc sort data = sashelp.shoes out = work.sortedshoes;
by descending product;

Proc sort data = work.shoes out = work.sortedshoes2;
by sales;

run;

....but the PRODUCT variable never still gets sorted in descending order. Please does anyone know what could be the issue?

Thanks!

Re: Proc sort issue

andreas_lds — Mon, 27 Jun 2022 07:07:03 GMT

Hardly possible to help without seeing the data used. Also please post the log, as text, so that we see what happened actually.

Re: Proc sort issue

Kurt_Bremser — Mon, 27 Jun 2022 08:05:46 GMT

The descending sort of product would only be visible within groups that share the same sales value. Since this is almost never the case:

 69         proc sort data=sashelp.shoes out=check nodupkey;
 70         by sales;
 71         run;
 
 NOTE: There were 395 observations read from the data set SASHELP.SHOES.
 NOTE: 3 observations with duplicate key values were deleted.
 NOTE: The data set WORK.CHECK has 392 observations and 7 variables.

the product values seem to not be sorted.

Re: Proc sort issue

tarheel13 — Mon, 27 Jun 2022 19:28:13 GMT

are you sure it's incorrect? show us a proc print of work.sortedshoes

Re: Proc sort issue

Tom — Mon, 27 Jun 2022 21:15:10 GMT

Show example data. You cannot sort a single dataset in two different ways.

Your first PROC SORT does what you asked for. Just look at the resulting dataset.

proc sort data = sashelp.shoes out = work.sortedshoes;
  by sales descending product;
run;

proc print data=sortedshoes (obs=10);
  var sales product;
run;

As you can see the values of SALES are increasing.

Obs           Sales    Product

  1            $325    Sandal
  2            $449    Sport Shoe
  3            $450    Sport Shoe
  4            $554    Sandal
  5            $601    Sandal
  6            $712    Sandal
  7            $736    Sandal
  8            $737    Sandal
  9            $801    Sport Shoe
 10            $936    Sport Shoe

To tell if the values of PRODUCT are decreasing within a given value of SALES just look at the observations that have the same value of SALES.

data dups;
  set sortedshoes;
  by sales;
  if not (first.sales and last.sales);
run;

proc print;
  var sales product;
run;

Result:

Obs           Sales    Product

 1           $1,190    Sandal
 2           $1,190    Sandal
 3           $1,520    Sandal
 4           $1,520    Boot
 5           $8,365    Sport Shoe
 6           $8,365    Boot

So you can see for the observations were SALES are 1,520 or 8,365 the two different values or PRODUCT are sorted in DESCENDING order just like you asked for.

Re: Proc sort issue

Dpeter — Wed, 29 Jun 2022 02:56:55 GMT

Thanks for your help. Tom's advise is really helpful.

Re: Proc sort issue

Dpeter — Wed, 29 Jun 2022 02:58:11 GMT

Thanks for your assistance. that was helpful.

Re: Proc sort issue

Dpeter — Wed, 29 Jun 2022 03:00:50 GMT

Hi Tom,
Thanks for your advise. I see that the Product variable is descending within the corresponding increasing sales variable. Thanks
This is really helpful. Thanks

Re: Proc sort issue

Dpeter — Wed, 29 Jun 2022 03:03:39 GMT

Thanks Andrea. Tom's advice is really helpful.