topic Re: Characters Count in New SAS User

Characters Count

Vasundha — Thu, 23 Jun 2022 03:12:43 GMT

Hi Everyone. I've a variable which has value like below. Here every part is seperated by / .

Data have;
Input Mass $30.;
datalines;
abcde1234&9&Y / defgh0987&2&N / attire1790&&4&Y
Daikin1290&6&Y / rets0987&2&N / attire1790&4&Y
;
run;

Required output;
Mass                                                     count1      count2 
abcde1234&9&Y / defgh0987&2&N / attire1790&&4&Y            2            1

Daikin1290&6&Y / rets0987&2&N / attire1790&4&Y             3            0

I require the count of & and && followed by numeric in two different fields named count1, count2.

For example : abcde1234&9&Y in this part the count1 is 1 and count2 is 0 ,because only one & is before 9

defgh0987&2&N in this part the count1 is 1 and count2 is 0 , because only one & is before 2.

attire1790&&4&Y in this part the count1 is 0 and count2 is 1, because there are 2 &'s before 4.

For your understanding purpose I differentiated them but it is a single value of Mass field. And also please do consider & and && 's count as 1 . For 1 & the count is 1 and for && the count is 1. Looking for some support. Thankyou!.

Re: Characters Count

Patrick — Thu, 23 Jun 2022 06:02:17 GMT

Not sure if you want a separate observation per sub-string separated by forward slash or not. Below code just counts over the full string.

data have;
  input mass $80.;
  datalines;
abcde1234&9&Y / defgh0987&2&N / attire1790&&4&Y
Daikin1290&6&Y / rets0987&2&N / attire1790&4&Y
;

data want;
  set have;
  /* create variable _mass with same length as mass */
  if 0 then _mass=mass;
  /* replace all digits with 1 */
  _mass=prxchange('s/\d+/1/oi',-1,strip(mass));
  /* count substrings */
  count2=count(_mass,'&&1');
  count1=count(_mass,'&1')-count2;
  drop _mass;
run;

proc print data=want;
run;

Re: Characters Count

Vasundha — Thu, 23 Jun 2022 06:27:06 GMT

This is exactly what I require. Please fill your heart heartily thanked.

Re: Characters Count

Patrick — Thu, 23 Jun 2022 12:13:09 GMT

@Vasundha If you're happy with a proposed answer then mark this answer as solution. This not only marks the question as answered, it also "rewards" the person who provided the most helpful answer.

Also don't hesitate to "like" other answers that you consider helpful.

Re: Characters Count

Ksharp — Thu, 23 Jun 2022 12:47:39 GMT

data have;
  input mass $80.;
  datalines;
abcde1234&9&Y / defgh0987&2&N / attire1790&&4&Y
Daikin1290&6&Y / rets0987&2&N / attire1790&4&Y
;

data want;
  set have;
count1=0;count2=0;
do i=1 to countw(mass,'/');
  temp=scan(scan(mass,i,'/'),1,'&','k');
  if strip(temp)='&' then count1+1;
  if strip(temp)='&&' then count2+1;
end;
run;