topic Re: Is there a way to check the values of a SAS char var that has numbers only? in New SAS User

Is there a way to check the values of a SAS char var that has numbers only?

cosmid — Thu, 28 Apr 2022 18:33:51 GMT

If a var is defined as char,

length x $6.;

How do I check the values of this var that has numbers only?

Example, if x has

12346

1a2b3c

1+abc

How do I find numeric values such as 12346?

Or is there a way to look for values that's alphabets? special chars?

Thanks!

Re: Is there a way to check the values of a SAS char var that has numbers only?

Reeza — Thu, 28 Apr 2022 18:55:03 GMT

Take a look at the ANY*/NOT* set of functions that will allow you to scan through, but they operate on each row not a column.

ANYALPHA will check variables for any alphabetical values for example.

Or if you're trying to convert you could just use the ?? options in INPUT

X_num = input(x, ?? 8.);

Which will convert anything to a valid number and suppress any warnings/messages to the log. Bit dangerous to use IMO but also has it's uses.

Re: Is there a way to check the values of a SAS char var that has numbers only?

Tom — Thu, 28 Apr 2022 18:59:50 GMT

An easy way to test if the value is a valid representation of a number is to try to convert it to a number.

Just use the normal numeric informat. Use the ?? modifier to suppress error messages.

data want;
  set have;
  number=input(x,??32.);
  valid_number = not missing(number);
run;

Or if you want to accept strings with commas and dollar signs ( like 1,200 and $5,000) then use the COMMA informat instead.

If X can hold strings that are longer than 32 bytes then you might want to also test that the value is not too long.

data want;
  set have;
  if length(strip(x))<=32 then number=input(strip(x),??32.);
  valid_number = not missing(number);
run;

Re: Is there a way to check the values of a SAS char var that has numbers only?

mklangley — Thu, 28 Apr 2022 19:01:17 GMT

Here's one way:

data have;
    input x $6.;
    length x $6.;
    datalines;
12346
1a2b3c
1+abc
abcde
    ;
run;

data string_with_only_numbers;
    set have;
    if anydigit(x) and not anyalpha(x);
run;

data string_with_only_alpha;
    set have;
    if not anydigit(x) and anyalpha(x);
run;

Courtesy of this post: https://communities.sas.com/t5/SAS-Procedures/Check-numeric-values-in-alphanumeric-variables/td-p/19247

Re: Is there a way to check the values of a SAS char var that has numbers only?

Ksharp — Fri, 29 Apr 2022 12:24:49 GMT

data have;
    input x $6.;
    length x $ 6;
flag=ifn(notdigit(strip(x)),0,1);
    datalines;
12346
1a2b3c
1+abc
abcde
;
run;