topic Re: Density plot of first and last decile of a quantitative variable in New SAS User

Density plot of first and last decile of a quantitative variable

mantubiradar19 — Sat, 21 Aug 2021 10:02:56 GMT

Hello everyone,

I would like to know how I can plot the density plot comparing the first and last decile group of a quantitive variable.

Thanks in advance

Re: Density plot of first and last decile of a quantitative variable

PaigeMiller — Sat, 21 Aug 2021 10:21:11 GMT

I don't understand. Compare first decile to last decile based on what criteria of comparison? I would think they are different by definition.

Re: Density plot of first and last decile of a quantitative variable

sbxkoenk — Sat, 21 Aug 2021 10:32:47 GMT

Hello,

Start here:

proc rank data=sashelp.heart(keep=height) out=work.heart_deciles groups=10;
   VAR height;
   RANKS height_decile;
run;

proc sort data=work.heart_deciles;
  by height_decile;
  where height_decile IN (0,9);
run;

proc sgplot data=work.heart_deciles;
  title "Height Distribution per decile";
  by height_decile;
  histogram height;
  density height;
  density height / type=kernel;
  keylegend / location=inside position=topright;
run;
title;
/* end of program */

With PROC SGPANEL, you can have both density plots in one graphical file (one "container").

Cheers,

Koen

Re: Density plot of first and last decile of a quantitative variable

PGStats — Sun, 22 Aug 2021 01:39:19 GMT

Usually, you would compare the distribution of a variable for groups defined by some other variable:

proc rank data=sashelp.heart(keep=weight cholesterol) out=work.heart_deciles groups=10;
   VAR weight;
   RANKS weight_decile;
run;

proc sort data=work.heart_deciles;
  by weight_decile;
run;

proc sgpanel data=work.heart_deciles;
  title "Cholesterol Distribution per Decile";
  where weight_decile in (0,9);
  panelby weight_decile / columns=1;
  histogram Cholesterol;
  density Cholesterol / type=kernel;
run;

Re: Density plot of first and last decile of a quantitative variable

mantubiradar19 — Mon, 23 Aug 2021 03:23:43 GMT

Hi Koen, many thanks. Let me try this code.