topic Re: removing gaps between treatment dates given a condition in New SAS User

removing gaps between treatment dates given a condition

DathanMD — Mon, 16 Aug 2021 06:05:55 GMT

I am junior with SAS and I would love your help.

I am dealing with a patient treatment dataset. Patients (patient) are receiving treatment (antibiotic) with a start date (start) and end dates (end) for each treatment. There are some gaps between the start and end dates but where such an interruption occurs and a patent re-starts the same antibiotic that has stopped within 5 days, this interruption should be treated as if the first treatment was continuous.

Eg have;

Patient	Antibiotic	start	End
1	cipro	16APR2018	21APR2018
1	cipro	23APR2018	29APR2018
2	Cipro,flagyl	16APR2018	16APR2018
2	Cipro,flagyl	23APR2018	29APR2018
2	cipro	30JUN2018	29JUL2018

Want

Patient	Antibiotic	start	End
1	cipro	16APR2018	29APR2018
2	Cipro,flagyl	16APR2018	29APR2018
2	cipro	30JUN2018	29JUL2018

Thanks a lot

Dathan

Re: removing gaps between treatment dates given a condition

andreas_lds — Mon, 16 Aug 2021 06:40:42 GMT

Please post the data in usable form. Similar questions are quite often asked and answered, it may be faster to use one of the existing solution and adept it to your needs, than waiting for a tailor-made solution.

Re: removing gaps between treatment dates given a condition

DathanMD — Mon, 16 Aug 2021 07:35:28 GMT

Thanks Andreas_lds for offering to help;

Below is the data in usable form ;

data have;
length antibiotic $200;
input patient antibiotic $ start:date9. end:date9.;
format start end date9.;
cards;
1 cipro 16APR2018 21APR2018
1 cipro 23APR2018 29APR2018
2 Cipro+flagyl 16APR2018 16APR2018
2 Cipro+flagyl 23APR2018 29APR2018
2 cipro 30JUN2018 29JUL2018
;
run;

data want;
length antibiotic $200;
input patient antibiotic $ start:date9. end:date9.;
format start end date9.;
cards;
1 cipro 16APR2018 29APR2018
2 Cipro+flagyl 16APR2018 29APR2018
2 cipro 30JUN2018 29JUL2018

;
run;

Re: removing gaps between treatment dates given a condition

andreas_lds — Mon, 16 Aug 2021 09:24:02 GMT

Why are 3rd and 4th obs combined? Between April, 16th and April, 23rd are more than five days, or have i misinterpreted your logic?

Re: removing gaps between treatment dates given a condition

DathanMD — Mon, 16 Aug 2021 09:29:23 GMT

Oops my mistake! I have twicked the data "have".

data have;
length antibiotic $200;
input patient antibiotic $ start:date9. end:date9.;
format start end date9.;
cards;
1 cipro 16APR2018 21APR2018
1 cipro 23APR2018 29APR2018
2 Cipro+flagyl 16APR2018 19APR2018
2 Cipro+flagyl 23APR2018 29APR2018
2 cipro 30JUN2018 29JUL2018
;
run;

;
run;

Re: removing gaps between treatment dates given a condition

andreas_lds — Mon, 16 Aug 2021 10:06:59 GMT

This is not the most beautiful or elegant solution:

proc sort data=work.have out=work.sorted;
   by Patient Antibiotic Start;
run;

data work.want;
   set work.sorted;
   by Patient Antibiotic;
   
   retain lastStart lastEnd;
   
   if first.Antibiotic then do;
      call missing(lastStart, lastEnd);
   end;
   else do;   
      if lastStart <= start <= (lastEnd + 5) then do;
         lastEnd = end;
      end;
      else do;   
         savedStart = start;
         savedEnd = end;
         start = lastStart;
         end = lastEnd;
         output;
         
         start = savedStart;
         end = lastEnd;
      end;
   end;
   
   lastStart = Start;
   lastEnd = End;
   
   if last.Antibiotic then do;
      output;
   end;
   
   /*format last: saved: date9.;*/
   
   drop last: saved:;
run;

Re: removing gaps between treatment dates given a condition

Ksharp — Mon, 16 Aug 2021 13:57:52 GMT

data have;
length antibiotic $200;
input patient antibiotic $ start:date9. end:date9.;
format start end date9.;
cards;
1 cipro 16APR2018 21APR2018
1 cipro 23APR2018 29APR2018
2 Cipro+flagyl 16APR2018 19APR2018
2 Cipro+flagyl 23APR2018 29APR2018
2 cipro 30JUN2018 29JUL2018
;
run;

data temp;
 set have;
 do date=start to end;
  output;
 end;
 format date date9.;
 drop start end;
run;
proc sort data=temp nodupkey;by patient antibiotic date;run;
data temp1;
 set temp;
 by patient antibiotic;
 if first.antibiotic or dif(date)>5 then group+1;
run;
proc summary data=temp1 ;
by group patient antibiotic;
var date;
output out=want min=start max=end;
run;