topic Re: Copy dynamic files from one folder to another in New SAS User

Copy dynamic files from one folder to another

hanrhub — Thu, 15 Jul 2021 10:55:42 GMT

Hello all,

I would like to copy all csv files from a specific folder to another one.

Below is the code which I am currently using:

data _null_;
length fref $8 fname $200;
did = filename(fref,'\\files\FEB_P000\Reporting_FS\Accounting log');
did = dopen(fref);
do i = 1 to dnum(did);
fname = dread(did,i);
IF find(FNAME,'.csv') then
do;
%let pathscr = //files/FEB_P000/Reporting_FS/Accounting log;
%let pathdes = //files/FEB_P000/Reporting_FS/Accounting log/2021;
%let file = FNAME;

libname IN "&pathscr";
libname IN "&pathdes";
filename src "&pathscr/&file";
filename des "&pathdes/&file";

rc= fcopy('src','des')

put rc=;

end;

run;

However when is executes, no error is displayed (rc= 20006) but the files are not copied.

When I hard code the variable '&file' with the exact file name, the file is copied.

Can anyone help please?

Re: Copy dynamic files from one folder to another

Tom — Thu, 15 Jul 2021 12:41:02 GMT

You appear to have placed some macro code into the middle of your data step. Since the data step does not run until after the macro processor has finished pre-processing the code and passing it to SAS itself to compile and run you should move those macro statements to BEFORE the DATA statement.

Same applies to the global statements (LIBNAME and FILENAME).

If you want to define a libname or a filename based on values you have in data use the LIBNAME() or FILENAME() functions. Not the LIBNAME or FILENAME statements.

Re: Copy dynamic files from one folder to another

andreas_lds — Thu, 15 Jul 2021 12:45:08 GMT

Do you have to use sas for this task? In a data step you need to use the filename function, not the filename statement.

Re: Copy dynamic files from one folder to another

Tom — Thu, 15 Jul 2021 12:47:31 GMT

Are you running this SAS code on Windows operating system of Unix? You can check the value of the SYSSCP macro variable.

Make sure the paths you use are consistent with where SAS is running.

Re: Copy dynamic files from one folder to another

hanrhub — Thu, 15 Jul 2021 12:52:15 GMT

Hello Tom,

Thanks for the explanations!
I am running it on Windows OS.

Could you propose me with the right solution in terms of my codes displayed above?

Thanks again

Re: Copy dynamic files from one folder to another

Tom — Thu, 15 Jul 2021 13:03:05 GMT

%let pathscr = \\files\FEB_P000\Reporting_FS\Accounting log;
%let pathdes = \\files\FEB_P000\Reporting_FS\Accounting log\2021;

data _null_;
  length fref $8 fname $256;
  did = filename(fref,"&pathsrc");
  did = dopen(fref);
  do i = 1 to dnum(did);
    fname = dread(did,i);
    if find(FNAME,'.csv ') then do;
      rc1=filename('src',catx('\',"&pathscr",fname));
      rc2=filename('des',catx('\',"&pathdes",fname));
      rc3=fcopy('src','des');
    end;
  end;
run;

Re: Copy dynamic files from one folder to another

Tom — Thu, 15 Jul 2021 12:59:23 GMT

See other post with code.

Since you are running on Windows you might want to make your search for CSV extension case insensitve.

find(FNAME,'.csv ','i')

Re: Copy dynamic files from one folder to another

hanrhub — Thu, 15 Jul 2021 13:03:20 GMT

Thanks a lot Tom!
It worked as expected 🙂