topic Re: Specific Value in Data set in New SAS User

Specific Value in Data set

Ernesto1 — Wed, 30 Jun 2021 07:41:04 GMT

I have following data

Description	number_1	number_2	number_3	total
Quantity	1	2	3	6
Value	10	20	30	60

I want to create
Description	number_1	number_2	number_3	total
Total ammount (quantity*value)	10	40	90	360

Re: Specific Value in Data set

PaigeMiller — Wed, 30 Jun 2021 12:34:00 GMT

This horizontal layout is a very poor choice for such a data set, and a long data set would make the programming easier. So, let's create a long data set, and then the calculations are trivial.

data have;
    input Description $	number_1	number_2	number_3	total;
    cards;
Quantity	1	2	3	6
Value	10	20	30	60
;

proc transpose data=have out=have_t;
    id description;
run;

data want;
    set have_t;
    total_amount=quantity*value;
run;

Hint: don't arrange your data in wide data sets if at all possible. Arrange your data in long data sets (such as data set HAVE_T in the code above) whenever possible, this make the programming much easier in most cases. See Maxim 19.

Re: Specific Value in Data set

Ksharp — Wed, 30 Jun 2021 12:33:57 GMT

Do you have IML ? it is easy for IML.

data have;
input Description $	number_1	number_2	number_3	total;
cards;
Quantity	1	2	3	6
Value	10	20	30	60
;

proc iml;
use have;
read all var _num_ into x[c=vname];

Description='Total ammount';
want=x[#,];
create want from want[c=vname r=Description];
append from want[r=Description];
close;
quit;


proc print;run;