topic Re: create new table sas studio in New SAS User

create new table sas studio

Sarra-Matri — Mon, 10 May 2021 17:41:03 GMT

From an imported tables, how can i create a new table that contains some columns?

Re: create new table sas studio

Kurt_Bremser — Mon, 10 May 2021 18:27:57 GMT

Use a data step, and the KEEP statement.

data want;
set have;
keep a b c;
run;

Re: create new table sas studio

ballardw — Mon, 10 May 2021 19:36:18 GMT

Or if you want to keep most of the variables and just remove a few, use Drop

data want;
    set have;
    drop P D Q;
run;

Re: create new table sas studio

Sarra-Matri — Tue, 11 May 2021 00:46:25 GMT

thank you for your reply but columns will be imported from multiple tables not just one

Re: create new table sas studio

Kurt_Bremser — Tue, 11 May 2021 13:19:43 GMT

Please don't hand out information in little bits and keep us guessing. Describe your issue as a whole.

Re: create new table sas studio

Sarra-Matri — Tue, 11 May 2021 16:27:34 GMT

i have a set of tables in my sas studio, from these tables i want to create a table which contains specific columns. and these columns do not belong to the same table

Re: create new table sas studio

Kurt_Bremser — Wed, 12 May 2021 10:48:31 GMT

So you probably need to merge or join the tables. Please show some examples for the tables, and what you intend to get as a result.

Re: create new table sas studio

Sarra-Matri — Wed, 12 May 2021 11:56:21 GMT

Re: create new table sas studio

Sarra-Matri — Wed, 12 May 2021 11:58:37 GMT

From the tables, i have to create a new table that contains the columns following: "account", "code", "country_label", "product_type", value.

Re: create new table sas studio

Kurt_Bremser — Thu, 13 May 2021 11:28:26 GMT

So what you do is a so-called "lookup" (expanding a code to a derived value).

There are several methods for doing this:

A SQL join:

proc sql;
create table want as
  select
    a.account,
    a.code,
    b.country_label,
    a.product_type,
    a.value
  from gsquarterly_december_2020 a
  left join
  country_classification b
  on a.country_code = b.country_code
;
quit;

Create a format:

data cntlin;
set country_classification;
fmtname = "country_label";
type = "C";
rename
  country_code=start
  country_label=label
;
keep fmtname type start label;
run;

data want;
set have;
country_label = put(country_code,country_label.);
keep account code country_label product_type value;
run;

A data step merge:

proc sort data=country_classification;
by country_code;
run;

proc sort data=gsquarterly_december_2020;
by country_code;
run;

data want;
merge
  gsquarterly_december_2020 (in=a)
  country_classification
;
by country_code;
if a;
keep account code country_label product_type value;
run;

or, most modern, a hash object:

data want;
set gsquarterly_december_2020;
if _n_ = 1
then do;
  length country_label $30; /* use appropriate length here */
  declar hash cc (dataset:"country_classification");
  cc.definekey("country_code");
  cc.definedata("country_label");
  cc.definedone();
end;
if cc.find() ne 0 then country_label = "";
keep account code country_label product_type value;
run;

Re: create new table sas studio

Sarra-Matri — Thu, 13 May 2021 12:05:27 GMT

Thank you so much for your help
I have an other question if you can help please
I want to classify account column by product then by country and do a graph.
How i can do that?

Re: create new table sas studio

Kurt_Bremser — Thu, 13 May 2021 12:23:11 GMT

Please supply an example for your dataset in a data step with datalines, so I have something to work with.

Describe how your graph should look like (line,bar,...) and what should be the X and Y axis values.

Re: create new table sas studio

Sarra-Matri — Thu, 13 May 2021 13:07:27 GMT

I have these tables and i want to classify column account (imports
/exports) by product then by country
then i should do a graph to the results

Re: create new table sas studio

Sarra-Matri — Thu, 13 May 2021 13:41:58 GMT