topic Re: Forest plot in New SAS User

Forest plot

Stefy67 — Mon, 03 May 2021 08:57:07 GMT

I want to produce a forest plot from my dataset here enclosed.

I write this code:

proc sgplot data=plot;
scatter x=pmr_max y=atc81chr1 / group=causa
xerrorlower=pmr_inf_max xerrorupper=pmr_sup_max
markerattrs=or (symbol=CircleFilled size=8 color=red) ;

run;

and this the result

I want to ask:

1. how can I have different colors for each causa

2. I would like to have the different PMR_max for each ATC81chr1 in column and not on the same line (see the last line 'Costruzioni navali').

Thanks for you help

Stefania

Re: Forest plot

Ksharp — Mon, 03 May 2021 10:30:18 GMT

You want this ?

proc summary data=sashelp.heart nway;
class Smoking_Status status;
var weight;
output out=have mean=mean lclm=lclm uclm=uclm;
run;
ods graphics/attrpriority=none;
proc sgplot data=have;
styleattrs datasymbols=(circlefilled diamondfilled) ;
scatter x=mean y=Smoking_Status/group=status groupdisplay=cluster xerrorlower=lclm xerrorupper=uclm;
yaxis colorbands=odd;
run;

Re: Forest plot

Stefy67 — Mon, 03 May 2021 11:00:03 GMT

Yes. Thanks.
May I choose colors for 'Status' ?

Re: Forest plot

Ksharp — Mon, 03 May 2021 11:15:58 GMT

proc summary data=sashelp.heart nway;
class Smoking_Status status;
var weight;
output out=have mean=mean lclm=lclm uclm=uclm;
run;
ods graphics/attrpriority=none;
proc sgplot data=have;
styleattrs datasymbols=(circlefilled diamondfilled) datacontrastcolors=(green purple);
scatter x=mean y=Smoking_Status/group=status groupdisplay=cluster xerrorlower=lclm xerrorupper=uclm;
yaxis colorbands=odd;
run;

Sure. Try this.

Re: Forest plot

Stefy67 — Mon, 03 May 2021 11:22:33 GMT

Yes, it works. Thanks a lot.

Last question: to produce this same graph for men and women should I use proc sgpanel?

Which option do you advise me?

Re: Forest plot

Ksharp — Mon, 03 May 2021 11:34:09 GMT

Answer is yes. Or run twice proc sgplot ,one for Male, another for Female.

proc summary data=sashelp.heart nway;
class sex Smoking_Status status;
var weight;
output out=have mean=mean lclm=lclm uclm=uclm;
run;
ods graphics/attrpriority=none;
proc sgpanel data=have;
panelby sex/layout=columnlattice novarname;
styleattrs datasymbols=(circlefilled diamondfilled) datacontrastcolors=(green purple);
scatter x=mean y=Smoking_Status/group=status groupdisplay=cluster xerrorlower=lclm xerrorupper=uclm;
rowaxis colorbands=odd;
run;

Re: Forest plot

Stefy67 — Mon, 03 May 2021 11:41:51 GMT

Thanks again.