topic to convert a character to numeric when character is not a specific recognised form in New SAS User

to convert a character to numeric when character is not a specific recognised form

Gopi2 — Wed, 07 Apr 2021 07:08:40 GMT

Hi Please help, thanks in advance.

I want to covert one of my columns that contains a character type in the form of the following --> e2/e2, e2/e3, e2/e4, e3/e3, e3/e4, and e4/e4 ( $5. format). I plan to convert this to the numeric variable before analysis.

such that

e2/e2 , e2/e3 and e3/e3 will be coded as 1

e2/e4, e3/e4 and e4/e4 will be coded as 2

I am not sure how to do this!

Please help. thanks in advance!

Re: to convert a character to numeric when character is not a specific recognised form

Kurt_Bremser — Wed, 07 Apr 2021 07:16:27 GMT

Create an informat:

data have;
input charvar $;
datalines;
e2/e2
e2/e3
e3/e3
e2/e4
e3/e4
e4/e4
;

proc format;
invalue convert
  "e2/e2" = 1
  "e2/e3" = 1
  "e3/e3" = 1
  "e2/e4" = 2
  "e3/e4" = 2
  "e4/e4" = 2
;
run;

data want;
set have;
numvar = input(charvar,convert.);
run;

Re: to convert a character to numeric when character is not a specific recognised form

Gopi2 — Wed, 07 Apr 2021 07:20:37 GMT

thanks a lot for your quick response!

Re: to convert a character to numeric when character is not a specific recognised form

Kurt_Bremser — Wed, 07 Apr 2021 07:40:00 GMT

You can also use a simple IF/THEN:

data want;
set have;
if charvar in ("e2/e2","e2/e3","e3/e3")
then numvar = 1;
else if charvar in ("e2/e4","e3/e4","e4/e4")
then numvar = 2;
run;

or a data step SELECT:

data want;
set have;
select (charvar);
  when ("e2/e2","e2/e3","e3/e3") numvar = 1;
  when ("e2/e4","e3/e4","e4/e4") numvar = 2;
  otherwise;
end;
run;

Re: to convert a character to numeric when character is not a specific recognised form

Gopi2 — Wed, 07 Apr 2021 23:37:29 GMT

thanks everything worked.