topic Export data to multiple sas7bdat files in New SAS User

Export data to multiple sas7bdat files

mmea — Thu, 25 Mar 2021 12:35:33 GMT

I have data with over 4 millions observations

How can I export these data to multiple sas7bdat files with 1 million observation in each file?

Re: Export data to multiple sas7bdat files

Kurt_Bremser — Thu, 25 Mar 2021 13:09:01 GMT

The question is: what for?

4 million observations ain't really much, so you're better off processing them at once.

Nevertheless, here's a little example:

%macro splits(inlib=,inds=,outlib=,outds=,split=);

%local num_ds i;

proc sql noprint;
select ceil(nobs/&split) into :num_ds from dictionary.tables
where libname = "&inlib." and memname = "&inds.";
quit;

data
%do i = 1 %to &num_ds.;
  &outlib..&outds.&i.
%end;
;
set &inlib..&inds.;
select (ceil(_n_/&split.));
%do i = 1 %to &num_ds.;
  when (&i) output &outlib..&outds.&i.;
%end;
end;
run;

%mend;

%splits(inlib=SASHELP,inds=CARS,outlib=WORK,outds=C,split=100)

Re: Export data to multiple sas7bdat files

Ksharp — Fri, 26 Mar 2021 11:44:08 GMT

The simplest code is:

data a b c d;
set have;
if _n_<=1000000 then output a;
else if _n_<=2000000 then output b;
else if _n_<=3000000 then output c;
else output d;
run;