topic Re: How to get a mean value for a variable by group? in New SAS User

How to get a mean value for a variable by group?

Danny2020 — Sun, 31 Jan 2021 21:40:22 GMT

I am trying to get the mean value for returns, but different companies contain different number of years, how could i figure these out? many thanks

ID	Year	Size	Return	Average
1	2016	sml	-2.1
1	2017	sml	0.25
1	2018	med	0.26	-0.26009
2	1999	sml	0.5
2	2000	med	-0.8
2	2001	med	0.7
2	2002	med	1.9	0.575

Re: How to get a mean value for a variable by group?

acordes — Sun, 31 Jan 2021 21:45:45 GMT

Proc Means Data=have;
Class ID;
Var return;
Output out=want mean= / autoname;
Run;

Re: How to get a mean value for a variable by group?

yabwon — Sun, 31 Jan 2021 21:53:50 GMT

Hi,

Two things:

1) how you get-0.26009 out of -2.1, 0.25, and 0.26?

2) do you want to get something like this:

data have;
input
ID 	Year 	Size $	Return 	;
cards;
1	2016	sml	-2.1	 
1	2017	sml	0.25	 
1	2018	med	0.26	
2	1999	sml	0.5	 
2	2000	med	-0.8	 
2	2001	med	0.7	 
2	2002	med	1.9	
;
run;
proc sort data = have;
  by ID year;
run;

data want;

  set have;
  by id;

  if first.ID then _avg = .;
  _avg + return;
  _n + (return>.z);

  if last.id then average = _avg/_n;
  drop _:;

  put _all_;
run;
proc print;
run;

Bart

Re: How to get a mean value for a variable by group?

Ksharp — Mon, 01 Feb 2021 12:05:15 GMT

data have;
input
ID 	Year 	Size $	Return 	;
cards;
1	2016	sml	-2.1	 
1	2017	sml	0.25	 
1	2018	med	0.26	
2	1999	sml	0.5	 
2	2000	med	-0.8	 
2	2001	med	0.7	 
2	2002	med	1.9	
;
run;
proc sql;
create table temp as
select *,mean(return) as mean from have group by id;
quit;
data want ;
 set temp;
 by id;
 if not last.id then call missing(mean);
run;