topic Re: How to put refline in a plot with percent sign in New SAS User

How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 08:38:22 GMT

I have this code for a SGPLOT:

PROC SGPLOT DATA = DATA PCTLEVEL=GROUP NOBORDER NOWALL ;
format DATE ddmmyyd10.;
VBAR DATE/ GROUP = TIME stat= percent NOOUTLINE grouporder= data ;
Title1 font = 'Calibri' height=16pt "TEST";
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
styleattrs DATACOLORS=(LightBlue STEEL MistyRose FireBrick);
RUN;

i wish to show a line from the y-axis at 80% on the plot, like this? How can I do that?

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 08:55:03 GMT

I'm guessing you already checked out the Refline Statement?

While the Refline Statement can not be used with Vbar, it can be used with VbarParm. See the chart here to see Compatible Statements in Proc SGPLOT.

Try using Vbarparm and Refline together 🙂

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:00:07 GMT

The vbarparm dosent work with my data.

in vbar I use dates as variable and my group is a string/labels

in vbarparm you have to have a numeric variable?

or am i wrong

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:00:56 GMT

Can you show a portion of your data?

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:05:43 GMT

My dataset i like this just with many more dates :

DATE	TIME
04JAN2021	same day
04JAN2021	same day
05JAN2021	same day
05JAN2021	same day
05JAN2021	next day
05JAN2021	next day

PROC SGPLOT DATA = TEST PCTLEVEL=GROUP NOBORDER NOWALL ;
format DATE ddmmyyd10.;
VBAR DATE/ GROUP = TIME stat= percent NOOUTLINE grouporder= data ;
Title1 font = 'Calibri' height=16pt "test";
keylegend / title="";
XAXIS DISPLAY=(NOLABEL);
YAXIS DISPLAY=(NOLABEL);
styleattrs DATACOLORS=(LightBlue STEEL MistyRose FireBrick);

RUN;

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:22:34 GMT

Takes a little pre-work, but see if you can use this as a template

data test;
input DATE $9. TIME $ 10-18;
datalines;
04JAN2021 same day
04JAN2021 same day
05JAN2021 same day
05JAN2021 same day
05JAN2021 next day
05JAN2021 next day
;

proc sort data=test;
   by date;
run;

proc freq data = test noprint;  
   by date; 
   tables time / out = temp;   
run;

proc sgplot data = temp;
   vbarparm category=date response=percent / group=time groupdisplay=stack;
   refline 80 / lineattrs=(thickness=5 color=black);
run;

Result:

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:27:36 GMT

thank you - but it says that percent is not found?

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:28:48 GMT

it works now!!

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:29:50 GMT

I'm glad you found your answer 🙂

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:30:52 GMT

Please remember to close the thread 🙂

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:36:34 GMT

I am just curious if I can change the order of my legend.

I have the labels "same day", "next day", "2 days after", "more than 2 days"

I wish to have that same order - but it mixes up in the plot.

I have sorted by date and also tried with time

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:40:44 GMT

What version of SAS do you use?

So you want them in that order in the Legend as well as in the actual plot, correct? With 'Same Day' in the bottom and so forth?

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:42:55 GMT

exactly - i tried actually to do grouporder = descending - and it worked?

But if you have a better way?

i use SAS 9.4

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:53:40 GMT

There are several ways to do this.

I would probably go this way

data test;
input DATE $9. TIME $ 10-26;
datalines;
04JAN2021 same day        
04JAN2021 same day        
05JAN2021 same day        
05JAN2021 same day        
05JAN2021 2 days after    
05JAN2021 2 days after    
05JAN2021 next day        
05JAN2021 next day        
05JAN2021 more than 2 days
05JAN2021 more than 2 days
;

proc sort data=test;
   by date;
run;

proc freq data = test noprint;  
   by date; 
   tables time / out = temp;   
run;

proc sql;
   create table plot as
   select * from temp
   order by date, whichc(time, "same day", "next day", "2 days after", "more than 2 days");
quit;

proc sgplot data = plot;
   vbarparm category=date response=percent / group=time groupdisplay=stack grouporder=data;
   refline 80 / lineattrs=(thickness=5 color=black);
run;

Result:

Re: How to put refline in a plot with percent sign

mmea — Tue, 12 Jan 2021 09:55:02 GMT

Thank you!!!!!!!!!

Re: How to put refline in a plot with percent sign

PeterClemmensen — Tue, 12 Jan 2021 09:55:45 GMT

Anytime.