topic Re: changing the value of a previous observation in New SAS User

changing the value of a previous observation

JeeAnTaeOo — Sat, 02 Jan 2021 19:29:28 GMT

There are two observations and I would like to change the variable "total" in the first observation to "55" without hardcoding

data final;
set overall;
total=n;
total+lag(n);
prpl=n/total;
run;

The code above is what I used to generate the table

Re: changing the value of a previous observation

Kurt_Bremser — Sat, 02 Jan 2021 19:35:21 GMT

You need a "look-ahead":

data final;
merge
  overall
  overall (
    firstobs=2
    keep=n
    rename=(n=_n)
  )
;
total = sum(n,_n);
run;

Untested; for tested code, provide your data as a data step with datalines.

Re: changing the value of a previous observation

Tom — Sat, 02 Jan 2021 19:52:13 GMT

Looks like you are trying to generate TOTAL, not move it from one observation to another.

You could just calculate the total and then combine it back onto the data set.

proc summary data=overall;
  var n;
  output out=total sum=total;
run;

data final;
  set overall;
  if _n_=1 then set total(keep=total);
  prpl=n/total;
run;

Here is a way to do it in one step:

data final;
  do until(eof1);
     set overall end=eof1;
     total+n;
  end;
  do until(eof2);
    set overall end=eof2;
    prpl=n/total;
    output;
  end;
run;