topic Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file in New SAS User

i am new to sas i have a data set with 5 variables i need the output given in attachment file

Aliya-begum — Sat, 17 Nov 2018 14:02:30 GMT

data VS;
input PT  VISITNO  HEIGHT   WEIGHT   PULSE  SBP;    
cards;
101 1 156 78 102 120
101 2 156 78 103 121
101 3 156 78 102 120
102 1 150 70 100 121
;
run;

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

VDD — Sat, 17 Nov 2018 14:22:46 GMT

Proc transpose should solve your needs.

https://support.sas.com/documentation/cdl/en/proc/61895/HTML/default/viewer.htm#a000063663.htm

https://stats.idre.ucla.edu/sas/modules/how-to-reshape-data-long-to-wide-using-proc-transpose/

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

novinosrin — Sat, 17 Nov 2018 14:47:29 GMT

data VS;
input PT  VISITNO  HEIGHT   WEIGHT   PULSE  SBP;    
cards;
101 1 156 78 102 120
101 2 156 78 103 121
101 3 156 78 102 120
102 1 150 70 100 121
;
run;

proc transpose data=vs out=w;
by pt visitno;
var height--sbp;
run;
proc sort data=w out=want;
by pt _name_;
run;

Rename/add labels to your convenience/needs

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

novinosrin — Sat, 17 Nov 2018 14:58:30 GMT

data VS;
input PT  VISITNO  HEIGHT   WEIGHT   PULSE  SBP;    
cards;
101 1 156 78 102 120
101 2 156 78 103 121
101 3 156 78 102 120
102 1 150 70 100 121
;
run;

data w;
set vs;
n=0;
array t height--sbp;
do over t;
v_name=vname(t);
ORRES=t;
n+1;
output;
end;
keep pt visitno v_name orres n;
run;

proc sort data=w out=want(drop=n);
by pt n;
run;

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

novinosrin — Sat, 17 Nov 2018 15:06:16 GMT

And something fancy

data VS;
input PT  VISITNO  HEIGHT   WEIGHT   PULSE  SBP;    
cards;
101 1 156 78 102 120
101 2 156 78 103 121
101 3 156 78 102 120
102 1 150 70 100 121
;
run;
data _null_;
if _n_=1 then do;
   dcl hash H (ordered: "A",multidata:'y') ;
   h.definekey  ("PT",'n') ;
   h.definedata ("PT", "VISITNO", "V_NAME","ORRES") ;
   h.definedone () ;
   end;
set vs end=lr;
n=0;
array t height--sbp;
do over t;
v_name=vname(t);
ORRES=t;
n+1;
h.add();
end;
if lr then h.output(dataset:'want');
run;

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

Aliya-begum — Sat, 17 Nov 2018 16:55:43 GMT

thank you for helping me

Re: i am new to sas i have a data set with 5 variables i need the output given in attachment file

Andygray — Sat, 17 Nov 2018 17:35:21 GMT

@Aliya-begum If the questions has been answered, you could mark as answered choosing one of the given solutions that you prefer.