topic Trim from right and left side by spaces in New SAS User

Trim from right and left side by spaces

Mchan890 — Thu, 17 Dec 2020 14:50:31 GMT

Value TEST - Group HS M228S Level 7 on SUPGRPPRF

Value TEST - Group HS M228S Level 6 - LF on SUPGRPPRF

Value TEST - Group HS M228S Level 6 - LF on GRP

Value TEST - Group HS M228S on SSGRP

I have the sample values above that needs to be trim from the left and right side. For example, I need the return values to be after the 3rd spaces from the left side and 2nd spaces from the right side.

Need return values:

Group HS M228S Level 7

Group HS M228S Level 6 - LF

Group HS M228S

Re: Trim from right and left side by spaces

Tom — Thu, 17 Dec 2020 16:59:51 GMT

Perhaps someone can figure out a regular expression for this, but for now why not just parse the sting into words and then re-build it using the words you want to keep.

data have;
 input str $80.;
cards;
Value TEST - Group HS M228S Level 7  on SUPGRPPRF
Value TEST - Group HS M228S Level 6 - LF on SUPGRPPRF
Value TEST - Group HS M228S Level 6 - LF on GRP
Value TEST - Group HS M228S Level 6 - LF on GRP
Value TEST - Group HS M228S Level 6 - LF on GRP
Value TEST - Group HS M228S on SSGRP
Value TEST - Group HS M228S on SSGRP
;

data want ;
  set have;
  length new $80;
  do i=4 to countw(str,' ')-2; new=catx(' ',new,scan(str,i,' ')); end;
  drop i;
run;
proc print width=min;
run;

Re: Trim from right and left side by spaces

ballardw — Thu, 17 Dec 2020 16:20:43 GMT

Or if the data is as regular as it appears:

data want ;
  set have;
  str = strip(tranwrd(str,'Value TEST - ',''));
  str = substr(str,1,indexw(str,' on ')-2);
run;

Re: Trim from right and left side by spaces

PGStats — Thu, 17 Dec 2020 20:15:13 GMT

Here is method based on regular expression matching:

data want;
if not prxId then prxId + prxparse("/Value TEST -\s+(.+)\s+on /i");
set have;
length value $80;
if prxmatch(prxId, str) then value = prxposn(prxId, 1, str);
drop prxId;
run;