topic Re: Changing Bar Colors in PROC SG PLOT in New SAS User

Changing Bar Colors in PROC SG PLOT

Allie_Haun — Thu, 10 Dec 2020 15:07:19 GMT

HI there,

I am having some difficulty changing the bar colors on my graphs.

Here is my code.

TITLE1 "Hypertension-Related Death Rates by State";
FOOTNOTE 'Created by Me';
PROC SGPLOT DATA = Hypertension.StatePercents;
		VBAR StateCd / Response=colpercent
							  GROUPDISPLAY=cluster
							  DATALABEL = ColPercent
							  ;
							  
	REFLINE 1.8
		/ AXIS = Y
		  LABELLOC = inside
		  LINEATTRS=(COLOR = INDIGO PATTERN = SHORTDASH)
		  LABEL = 'National Average = 1.8';
		  
	XAXIS LABEL = 'State Code'
		  LABELATTRS= (WEIGHT = BOLD)
		  ;
		  
	STYLEATTRS DATACOLORS= (LIGHTSALMON)
			   DATACONTRASTCOLORS= (BLACK)
			   ;
			   
	YAXIS LABEL = 'PERCENT'
		  OFFSETMIN= 0
		  LABELATTRS= (WEIGHT = BOLD)
		  VALUES = (0,1,2,3,4)
		  GRID;
RUN;
TITLE;
FOOTNOTE;

my output is still using blue bars instead of salmon, any ideas?

Re: Changing Bar Colors in PROC SG PLOT

ballardw — Wed, 09 Dec 2020 00:05:27 GMT

To change all bars to use the same color use the FILLATTRS option on the VBAR statement.

VBAR StateCd / Response=colpercent
		GROUPDISPLAY=cluster
		DATALABEL = ColPercent
               Fillattrs=(color=lightsalmon)
 ;

Your Styleattrs requires at least one GROUP= variable in a plot statement

Requirement For this option to have an effect, at least one plot statement in the procedure must specify the GROUP= option.

Re: Changing Bar Colors in PROC SG PLOT

Reeza — Wed, 09 Dec 2020 00:05:32 GMT

Specify the color?

VBAR StateCd / Response=colpercent
GROUPDISPLAY=cluster
DATALABEL = ColPercent
FILL
FILLATTRS=(color = "cxffa07a")
;

I just googled the code for light salmon so you may need to change that. The CX should be in front if you're using Hex codes.
Otherwise, specify your colour using any of these specifications:
https://documentation.sas.com/?cdcId=pgmsascdc&cdcVersion=9.4_3.5&docsetId=graphref&docsetTarget=p0edl20cvxxmm9n1i9ht3n21eict.htm&locale=en