topic Re: setting length of character variables without changing order in New SAS User

setting length of character variables without changing order

archita — Thu, 03 Dec 2020 07:00:52 GMT

i have a dataset with more than 100 variables , I want to set the length of all character variables without changing their order. how to get this ?

Re: setting length of character variables without changing order

andreas_lds — Thu, 03 Dec 2020 07:05:51 GMT

@archita wrote:

i have a dataset with more than 100 variables , I want to set the length of all character variables without changing their order. how to get this ?

Do you want to change all variable to have the same length?

Do you know how to change the length of one variable?

Re: setting length of character variables without changing order

PeterClemmensen — Thu, 03 Dec 2020 07:10:31 GMT

Should all character variables have the same length?

Re: setting length of character variables without changing order

archita — Thu, 03 Dec 2020 07:18:43 GMT

i want to change all the variable to same length without changong their order

Re: setting length of character variables without changing order

archita — Thu, 03 Dec 2020 07:22:50 GMT

yes

Re: setting length of character variables without changing order

andreas_lds — Thu, 03 Dec 2020 07:42:14 GMT

proc sql seems to be a good choice to solve the problem.

/* create a dataset that can be modified */
data work.class;
   set sashelp.class;
run;

/* the view will contain all char-variables ordered by their appearance in the dataset */
proc sql noprint;
   create view work.vars as
      select Name
         from sashelp.vcolumn
            where Libname = 'WORK'
               and MemName = 'CLASS'
               and Type = 'char'
         order by Varnum
   ;
quit;

/* creates and executes a proc-sql-step setting the length of all char-variables to 42 - the generated code is written to the log */
data _null_;
   set work.vars end= jobDone;

   if _n_ = 1 then do;
      call execute('proc sql noprint;');
      call execute('alter table work.class');
      call execute('modify ');
   end;
   
   call execute(catx(' ', Name, 'char(42)', ifc(not JobDone, ',', '')));

   if jobDone then do;
      call execute('; quit;');
   end;
run;

Re: setting length of character variables without changing order

archita — Thu, 03 Dec 2020 08:39:58 GMT

I need it only by data step.

Re: setting length of character variables without changing order

FreelanceReinh — Thu, 03 Dec 2020 09:09:52 GMT

@archita wrote:
I need it only by data step.

This is similar to @andreas_lds's approach:

data _null_;
call execute('data have; length');
do until(last);
  set sashelp.vcolumn end=last;
  where libname='WORK' & memname='HAVE';
  call execute(catx(' ',name,ifc(type='char','$42',put(length,1.))));
end;
call execute('; set have; run;');
stop;
run;