topic Re: extract words in New SAS User

extract words

Annie_Fréchette — Mon, 19 Oct 2020 12:55:23 GMT

Hi, I'm working with bacteria names and here is what I would like to do. Each animal may have up to 5 types of bacteria. I want to count all the staphylococci that are not aureus. My first step would surely be to separate the genus and species in two variables... but I'm not sure how.... Or is it possible to simply calculate all the sample that have "staphylococcus" as first word and NOT "aureus as the second word?

My data are sensitive but I,m gonna create a little example

In the end, I want to create a binary variable, if one of the 5 species of the cow

data r_mam;
input cow SP_1$ SP_2$ SP_3$ SP_4$ SP_5$;
cards;
1 Streptoccous dysgalactiae Klebsiella pneumoniae Staphylococcus chromogenes
2 Staphylococcus aureus Staphylococcus xylosus Escherichia coli
3 Streptococcus uberis
;
run;

was a non-aureus Staphylococci, the variable is 1.

Thank you very much for your help!!!

Re: extract words

PaigeMiller — Mon, 19 Oct 2020 13:09:23 GMT

@Annie_Fréchette wrote:

Hi, I'm working with bacteria names and here is what I would like to do. Each animal may have up to 5 types of bacteria. I want to count all the staphylococci that are not aureus. My first step would surely be to separate the genus and species in two variables... but I'm not sure how....

data r_mam;
	infile cards truncover;
	input cow SP_1 :$16. SP_2 :$16. SP_3 :$16. SP_4 :$16. SP_5 :$16.;
	cards;
1 Streptoccous dysgalactiae Klebsiella pneumoniae Staphylococcus chromogenes
2 Staphylococcus aureus Staphylococcus xylosus Escherichia coli
3 Streptococcus uberis
;
run;
data want;
	set r_mam;
	array a sp_1 sp_3 sp_5;
	array b sp_2 sp_4 sp_6;
	do i=1 to dim(a);
		if not missing(a(i)) then genus=a(i);
		if not missing(b(i)) then species=b(i);
		if not missing(a(i)) then output;
	end;
	drop sp_: i;
run;

Re: extract words

andreas_lds — Mon, 19 Oct 2020 13:11:41 GMT

The provided data-step does not work as expected: text is truncated ...

Is this as close as possible to what you have:

data r_mam;
   length
      cow 8
      SP_1-SP_5 $ 40
   ;
   infile datalines4 delimiter=';' missover;
   input cow SP_1 SP_2 SP_3 SP_4 SP_5;
   datalines4;
1;Streptoccous dysgalactiae;Klebsiella pneumoniae;Staphylococcus chromogenes
2;Staphylococcus aureus;Staphylococcus xylosus;Escherichia coli
3;Streptococcus uberis
;;;;
run;

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 13:14:56 GMT

yes this is correct!

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 13:20:15 GMT

Hi Paige, thank but it is not doing the right thing... each variable SP_ contain these infos (genus specie)

I would like to have on one line Genus_1 specie_1 Genus_2 specie_2 etc....

Thanks!

Re: extract words

Cynthia_sas — Mon, 19 Oct 2020 13:24:47 GMT

The original data example just had spaces in the raw data lines. In the above example, each pair is separated by semi-colons. This tiny piece of information will impact how the data needs to be read. Can you explain how your data actually looks? Like your first example or like shown in @andreas_lds example (with semi-colons)?

Cynthia

Re: extract words

andreas_lds — Mon, 19 Oct 2020 13:29:26 GMT

@Annie_Fréchette wrote:

yes this is correct!

You can use scan to look at each word or regular expressions.

What do you expect as result? The cows with staphylococcus, but not aureus? Or just the count?

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 13:30:01 GMT

Hi! I just wanted to give you an example of what I'm dealing with. My data are from an access file and between the Genus and species ther is a space (in SP_1, SP_2 etc)... Not sure how to explain better ... sorry!

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 13:32:32 GMT

What I want in the end is : if one of the Sp_1/SP_2/ etc was Staphylococci genus but Not an aureus species, SNA(a new binary variable)=1

Re: extract words

andreas_lds — Mon, 19 Oct 2020 13:36:13 GMT

Like this?

data cows;
   set work.r_mam;

   length all $ 200 sna 8;

   all = catx(' ', of sp_1-sp_5);

   sna = prxmatch('/staphylococcus (?!aureus)/i', all) and not prxmatch('/staphylococcus aureus/i', all);

   drop all;
run;

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 13:50:38 GMT

Thank you very much! Can I ask you one more question? I don't see in the code how Sas know to attribute "1" for the SNA? Where it is write?

Thanks again!

Re: extract words

Cynthia_sas — Mon, 19 Oct 2020 13:58:34 GMT

Hi:

What if a cow has THIS row of data with 2 types of Staphylococcus values, one aureus and one not:

2 Staphylococcus aureus Staphylococcus xylosus Escherichia coli

Then what would your binary variable look like? SNA=1 ?

What about this?

9 Staphylococcus aureus Staphylococcus xylosus Staphylococcus chromogenes Escherichia coli

Would SNA=1 or would SNA=2?

Cynthia

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 14:08:05 GMT

Good point!

In your first line SNA=1, and I have another binary variable S.aureus=1

In your second line SNA also=1, it's a binary variable, not a sum.

Annie

Re: extract words - how about this?

SASJedi — Mon, 19 Oct 2020 14:20:24 GMT

How about something like this:

data r_mam;
   length cow flag 8 ;
   array sp_[5] $ 40;
   infile datalines4 delimiter=';' missover;
   input cow SP_1 SP_2 SP_3 SP_4 SP_5;
   do i= 1 to dim(SP_);
      SP_[i]=lowcase(SP_[i]);
      flag=max(flag,(find(SP_[i],'staphylococcus') and not find(SP_[i],'aureus')));
      put sp_[i]= flag=;
   end;
   drop i;
datalines4;
1;Streptoccous dysgalactiae;Klebsiella pneumoniae;Staphylococcus chromogenes
2;Staphylococcus aureus;Staphylococcus xylosus;Escherichia coli
3;Streptococcus uberis;Staphylococcus aureus
;;;;
run;

The result looks like this:

Obs	cow	flag	sp_1	sp_2	sp_3
1	1	1	streptoccous dysgalactiae	klebsiella pneumoniae	staphylococcus chromogenes
2	2	1	staphylococcus aureus	staphylococcus xylosus	escherichia coli
3	3	0	streptococcus uberis	staphylococcus aureus

Re: extract words

Annie_Fréchette — Mon, 19 Oct 2020 14:20:43 GMT

Hi @andreas_lds !

@Cynthia_sasraised up a good point... that is problematic at this moment with the code.... If a cow have a Staphylocooccus aureus AND a Staphylococcus xylosus I would lik my SNA=1.. presently this is not the case...

Re: extract words - how about this?

Annie_Fréchette — Mon, 19 Oct 2020 14:55:04 GMT

Thanks! This has resolved my exceptions!

Have a nice day!

Re: extract words

andreas_lds — Tue, 20 Oct 2020 04:21:52 GMT

@Annie_Fréchette wrote:

Hi @andreas_lds !

@Cynthia_sasraised up a good point... that is problematic at this moment with the code.... If a cow have a Staphylocooccus aureus AND a Staphylococcus xylosus I would lik my SNA=1.. presently this is not the case...

Of course not, because you have defined the flag-variable differently. But you still want sna = 0, if you find Staph. aureus and, e.g. Staph. epidermis (don't know if that is possible) are found? Please be precise! Maybe defining sna=0 is easier, if in understood all your posts, you want sna = 0 if

a) the only Staphylococcus found is aureus, or

b) no Staph. is found at all.

Right?

Re: extract words

Annie_Fréchette — Tue, 20 Oct 2020 17:49:25 GMT

Hi Andreas! Sorry if my toughts were not clear about I wanted. I used the code from @SASJedi and it worked as I needed!

Thanks agains for your help!

Annie