topic How to export library of SAS files as .csv files? in New SAS User

How to export library of SAS files as .csv files?

AbOnTheCob — Wed, 23 Sep 2020 21:05:11 GMT

I have a folder of SAS data files. My goal is to take each of those files and convert it into a csv file. I want all those csv files to be in their own folder. Thus, I will have one folder of the initial SAS files, as well as one folder of the respective csv files.

I know how to convert individual SAS files to csv, but I'm not sure how to do it across an entire library.

Also, I need the csv files to have the same name as the respective SAS files, except with a .csv at the end, obviously.

Re: How to export library of SAS files as .csv files?

Kurt_Bremser — Wed, 23 Sep 2020 22:16:59 GMT

Retrieve the dataset names for a library from SASHELP.VTABLE in a DATA _NULL_ step, and use CALL EXECUTE to create the PROC EXPORT code for each.

Re: How to export library of SAS files as .csv files?

AbOnTheCob — Thu, 24 Sep 2020 19:47:05 GMT

Hi, thanks for the response. Sorry to bother but could you elaborate on how to retrieve the dataset names from sashelp.vtable? I understand I need to do

data _null_;
set sashelp.vtable;

but I'm not sure where to go from there. Thanks!

Re: How to export library of SAS files as .csv files?

Kurt_Bremser — Thu, 24 Sep 2020 20:17:27 GMT

data _null_;
set sashelp.vtable;
where libname = "YOUR_LIB"; /* all uppercase! */
call execute("
  proc export
    data=YOUR_LIB." !! strip(memname) !! "
    outfile='path_to_your_files/" !! lowcase(strip(memname)) !! ".csv'
    dbms=csv
    replace
  ;
  run;
");
run;

Untested, posted from my tablet.

Re: How to export library of SAS files as .csv files?

Reeza — Fri, 25 Sep 2020 18:23:34 GMT

Here's a full solution.

Change the library at the top of the program and the path to where you want the files to be saved and it will dynamically create the folders and files for you.

options dlcreatedir;

proc options option=dlcreatedir;
run;

*SET THESE TO BE FOR YOUR CODE;
%let lib2export = WORK;
%let path2files = /home/demo/;


*DO NOT CHANGE BELOW;


data _null_;
*list of files;
set sashelp.vtable(where = (libname = "&lib2export") keep = libname memname);

*create folder path for files to be stored;
folder4file = catt("&path2files.", memname);

*use libname to create folders;
rc_open = libname('demo1', folder4file) ;
rc_close = libname('demo1');

file2export = catt(folder4file, "/", memname, ".csv");

*export file;
length str $300.;
str = catt("proc export data=", 
			"&lib2export.", 
			".",
			memname, 
			" outfile=",
			trim(quote(file2export)),
			" dbms=csv replace;run;");
			
call execute (str);

run;

If you want to understand the code, I would suggest saving it to a data set and then examining the data set.

data _null_;

*becomes;

data exportFiles;

If you need to debug it, comment out the CALL EXECUTE line and make sure the code generated in STR is correct.

@AbOnTheCob wrote:

I have a folder of SAS data files. My goal is to take each of those files and convert it into a csv file. I want all those csv files to be in their own folder. Thus, I will have one folder of the initial SAS files, as well as one folder of the respective csv files.

I know how to convert individual SAS files to csv, but I'm not sure how to do it across an entire library.

Also, I need the csv files to have the same name as the respective SAS files, except with a .csv at the end, obviously.

Re: How to export library of SAS files as .csv files?

SmasherDA — Fri, 14 Jul 2023 18:43:57 GMT

Thank you, Kurt. This worked perfectly (as compared to all the other posted methods online which did not work at all for me).