topic Re: set function with macro in New SAS User

set function with macro

dustychair — Sat, 19 Sep 2020 21:26:58 GMT

Hi all,

I have a question on combining some data sets with macro. I have 4 tests and 12 grades. I would like to combine all of the grades for each relevant test. I don't get any error with the below code but it is taking only grade 12. Could you help me with what I am missing?

Thanks

%macro combine(k);
data &k._pl_all_n;
%do i=1 %to 12;
set pls_&k._gr_&i. ;
%end;
run;
%mend;
%combine(listening);
%combine(writing);
%combine(speaking);
%combine(reading);

Re: set function with macro

PGStats — Sat, 19 Sep 2020 21:34:51 GMT

You need a SET statement with a list of datasets, not a list of set statements where each overwrites the preceeding:

%macro combine(k);
data &k._pl_all_n;
set 
%do i=1 %to 12;
    pls_&k._gr_&i.
    %end;
; 
run;
%mend;

Re: set function with macro

PGStats — Sat, 19 Sep 2020 21:40:10 GMT

Note that you could just as well use a dataset list:

%macro combine(k);
data &k._pl_all_n;
set pls_&k._gr_1 - pls_&k._gr_12;
run;
%mend;

Re: set function with macro

Kurt_Bremser — Sat, 19 Sep 2020 21:40:28 GMT

Your macro creates these statements (SET is a statement, not a function!):

set pls_listening_gr_1;
set pls_listening_gr_2;
set pls_listening_gr_3;
set pls_listening_gr_4;
set pls_listening_gr_4;
set pls_listening_gr_5;
set pls_listening_gr_6;
set pls_listening_gr_7;
set pls_listening_gr_8;
set pls_listening_gr_9;
set pls_listening_gr_10;
set pls_listening_gr_11;
set pls_listening_gr_12;

so the data step reads an observation each from all 12 datasets (overwriting the PDV each time), and only the data from the last read remains to be written to the output dataset.

Move the SET statement out of the macro loop:

%macro combine(k);
data &k._pl_all_n;
set
%do i=1 %to 12;
  pls_&k._gr_&i.
%end;
;
run;
%mend;

Re: set function with macro

dustychair — Sat, 19 Sep 2020 21:42:45 GMT

Thank you so much!