topic Re: Help with Frequencies in New SAS User

Help with Frequencies

marleeakerson — Thu, 17 Sep 2020 18:02:10 GMT

Hello,

I am trying to run a frequency but need some help.

Using this sample data set:

ID Result

1 Pos

1 Neg

2 Pos

2 Neg

2 Pos

3 Pos

4 Neg

4 Pos

I am trying to run a frequency to see the frequency of people (IDs) who went from positive to negative, how many went from negative to positive, and all the other combinations (pos to neg and then back to pos, etc.).

Can someone help me out with this?

Thank you!

Re: Help with Frequencies

Kurt_Bremser — Thu, 17 Sep 2020 19:04:48 GMT

Prepare counts for changes:

data prefreq;
set have;
by id;
_result = lag(result);
if first.id
then do;
  count_neg_to_pos = 0;
  count_pos_to_neg = 0;
end;
else do;
  if _result = "Neg" and result = "Pos" then count_neg_to_pos + 1;
  if _result = "Pos" and result = "Neg" then count_pos_to_neg + 1;
end;
if last.id;
drop result_result;
run;

Re: Help with Frequencies

FreelanceReinh — Thu, 17 Sep 2020 20:18:15 GMT

Hello @marleeakerson,

@marleeakerson wrote:

I am trying to run a frequency to see the frequency of people (IDs) who went from positive to negative, how many went from negative to positive, and all the other combinations (pos to neg and then back to pos, etc.).

Do you want to count an ID with, e.g., Pos followed by Neg in the same category as an ID with four times Pos followed by three times Neg (because both went from Pos to Neg), but not in the same category as an ID that after this change switched back to Pos?

If so, try this:

data want;
length seq $100;
do until(last.id);
  set have;
  by id result notsorted;
  if first.result then seq=catx(',', seq, result);
end;
drop result;
run;

proc freq data=want;
tables seq;
run;

This assumes that your dataset (HAVE) is sorted by ID. (Add a PROC SORT step if this is not the case.) Adapt the length of character variable SEQ (100) as needed to accommodate the relevant sequences "Pos,Neg,Pos,..." etc.