topic Re: Display mean on boxplot with sgpanel in New SAS User

Display mean on boxplot with sgpanel

hinashah — Sat, 25 Jul 2020 19:04:57 GMT

I have an sgpanel where I want to show categorical boxplots inside each panel. For these boxplots, I'd like to display the mean quantity. However, I can't find a way to do this. Is it possible? Here's my proc sgpanel, and the result is below. I'd like to display the value for mean on this panel for each of the box.

proc sgpanel data=new_one;
panelby testtrain;
vbox diff/category=category nooutliers group=category transparency=0.3;
refline 0/axis=Y lineattrs=(colors=black thickness=2);
run;

Re: Display mean on boxplot with sgpanel

ballardw — Sun, 26 Jul 2020 07:02:15 GMT

Mean quantity of what variable? Within group?

Here is an example that may help using the SASHELP.Class dataset that plots VBox of weight by age, paneled by sex.

Basically it involves calculating the mean of whatever and then overlaying a scatter plot to show the value.

proc sort data=sashelp.class
   out=work.class;
   by sex;
run;

proc summary data=work.class nway;
   class sex age;
   var weight;
   output out=work.summary(drop=_:) mean=meanweight;
run;

data work.plot;
   set work.class
       work.summary
   ;
run;

proc sgpanel data=work.plot;
   panelby sex;
   vbox weight /category=age group=age ;
   scatter x=age y=meanweight /markerchar=meanweight;
run;

Since the format associated with Meanweight by default is a BEST you may want to specify a format to display fewer decimals.

Re: Display mean on boxplot with sgpanel

hinashah — Fri, 31 Jul 2020 15:41:21 GMT

Thanks for your reply! I used your suggestion, and changed my code to something like this. I did want the mean to be displayed for the variable diff. Used the datalabel for scatter, and also added a colaxistable.

proc summary data=new_one nway;
	class testtrain category;
	var diff;
	output out=new_summary(drop=_:) mean=meandiff;
run;

data for_panel;
	set new_one new_summary;
run;

proc sgpanel data=for_panel;
	panelby testtrain ;
	vbox diff/category=category nooutliers group=category datalabel ;
	scatter x=category y=meandiff / datalabel=meandiff markerattrs=(size=1px);
	rowaxis values= (0 to 150 by 7) grid label='difference';
	refline 0 / axis=Y lineattrs=(color=black thickness=1);
	colaxistable diff /X=category stat=mean label='mean' separator;
	title 'Difference from Ground Truth';
run;

Here's the result:

Thanks for your suggestion!!