topic Re: Variable in New SAS User

Variable

honeyblue — Wed, 22 Jul 2020 03:50:54 GMT

I have a variable name with value NaveenKumar, HarishChandra, SivaKumar

But I want to separate as firstname and last name

ex Firstname ------------Naveen lastname ----Kumar

Re: Variable

andreas_lds — Wed, 22 Jul 2020 05:07:19 GMT

@honeyblue wrote:

I have a variable name with value NaveenKumar, HarishChandra, SivaKumar

But I want to separate as firstname and last name

ex Firstname ------------Naveen lastname ----Kumar

Do you have one variable containing the complete string or is the comma meant to separate observations?

Re: Variable

andreas_lds — Wed, 22 Jul 2020 05:14:04 GMT

Try:

data have;
   length name $ 40;
   input name;
   datalines;
NaveenKumar
HarishChandra
SivaKumar
;
run;

data want;
   set have;
   
   length firstname lastname $ 30;
   retain rx;
   drop rx;
   
   if _n_ = 1 then do;
      rx = prxparse('/([A-Z][a-z]+)([A-Z][a-z]+)/');
   end;
   
   if prxmatch(rx, name) then do;
      firstname = prxposn(rx, 1, name);
      lastname = prxposn(rx, 2, name);
   end;
   else do;
      put 'ERROR: Unable to extract firstname/lastname from data';
      put _all_;
   end;
run;