topic Re: macro variable in macro name in New SAS User

macro variable in macro name

Quodly — Fri, 15 Nov 2019 07:54:00 GMT

running

%let var = 1;

%macro mac_&var.;
  %put emmanuel macro;
%mend;

%mac_1;

gives

1      %let var = 1;
2
3      %macro mac_&var.;
ERROR: Expected semicolon not found.  The macro will not be compiled.
ERROR: A dummy macro will be compiled.
4        %put emmanuel macro;
5      %mend;
6
7      %mac_1;
       -
       180
WARNING: Apparent invocation of macro MAC_1 not resolved.

ERROR 180-322: Statement is not valid or it is used out of proper order.

what's wrong with it? can't i use macro variables in the definition of macros?

Re: macro variable in macro name

PeterClemmensen — Fri, 15 Nov 2019 08:02:57 GMT

As the %MACRO Statement Documentation says:

"you cannot use a text expression to generate a macro name in a %MACRO statement."

Re: macro variable in macro name

ballardw — Fri, 15 Nov 2019 17:02:27 GMT

If you can describe why you thought you needed this sort of naming we may be able to provide alternate approaches to accomplish something similar.

Re: macro variable in macro name

Tom — Fri, 15 Nov 2019 19:38:08 GMT

You seem to confused.

Did you mean to do something like this instead?

%macro mac_1;
  %put First Macro ;
%mend;
%macro mac_2;
  %put Second Macro ;
%mend;
....
%let var = 1;
%mac_&var. ;

Re: macro variable in macro name

Quodly — Wed, 04 Dec 2019 11:06:24 GMT

sorry for my late reply. i wanted to define macros inside a macro loop, each macro named differently. i did it another way now. thanks anyway!

Re: macro variable in macro name

Tom — Wed, 04 Dec 2019 13:06:55 GMT

You do not ever need (or want) to redefine a MACRO inside of a loop. Perhaps instead you meant that you want to define a new macro VARIABLE in a loop?
%do i=1 %to %sysfunc(countw(&list,%str( ))); %let element=%scan(&list,&I,%str( )); .... %end;
Or you meant to CALL a macro inside the loop?
%do i=1 %to %sysfunc(countw(&list,%str( ))); %sub_macro(%scan(&list,&I,%str( ))); %end;

Re: macro variable in macro name

ishmo65 — Fri, 24 Apr 2020 10:35:10 GMT

Is there any way I can do this ?

;;;;;
options mprint mlogic symbolgen;
options mautocomploc;
%let macroname=temp;

%sysmacdelete &macroname.;

%macro &macroname.(var1,var2);
	%put Macro started: &macroname.;
	%put ===============================;

/* macro code here */

	%put Macro ended: &macroname.;
	%put =============================;

%mend &macroname.;

data _null_;
	attrib a format=1.;
	/* check log for the following message from the put statement */
	put "Macro ran successfully - delimiters (e.g. single/double quotes ok";
	a=%sysmacexist(&macroname.);
	put a=;
	if a=1 then
		put "&macroname. created successfully";
	else
		put "&macroname. not created - check for errors";
run;

The code outside of the macro works but the macro create fails with:

11049  %macro &macroname.(var1,var2);
ERROR: Invalid macro name &.  It should be a valid SAS identifier no longer than 32 characters.
...
11281  %mend &macroname.;
WARNING: Extraneous text on %MEND statement ignored for macro definition .

Re: macro variable in macro name

ishmo65 — Fri, 24 Apr 2020 10:50:58 GMT

My solution (which I've finalised since my last response is to hardcode the macro name as:
%macro temp;
conclude it with:
%mend temp;
then check temp is created:
data _null_;
attrib a format=1.;
/* check log for the following message from the put statement */
put "Macro ran successfully - delimiters (e.g. single/double quotes ok";
a=%sysmacexist(temp);
put a=;
if a=1 then
put "Macro temp created successfully";
else
put "Macro temp not created - check for errors";
run;
and then rename the macro:
proc catalog cat=work.sasmacr;
change temp=&macroname. /et=macro;
run;
Then use the original final step to check the rename has worked:
data _null_;
attrib a format=1.;
/* check log for the following message from the put statement */
put "Macro ran successfully - delimiters (e.g. single/double quotes ok";
a=%sysmacexist(&macroname.);
put a=;
if a=1 then
put "Macro &macroname. created successfully";
else
put "Macro &macroname. not created - check for errors";
run;

Re: macro variable in macro name

ishmo65 — Fri, 24 Apr 2020 11:19:16 GMT

That didn't wok - running the macro resulted in the following errors:
ERROR: The macro name XYZ and the internal macro header name TEMP in the SASMACR macro catalog differ. Recompile this macro and try again.
ERROR: Macro library damaged. Cannot execute macro XYZ on V9.x compiled using V9.3x on DDMMYY.

Re: macro variable in macro name

Tom — Fri, 24 Apr 2020 12:20:16 GMT

Not sure why you posted a new question into an old thread. But the answer is still the same. You cannot use macro variables to generate the %MACRO statement. I doubt there is any real problem that requites that you do that, but if insist on dynamically generating code to create a %MACRO statement then use some other method of code generation. Such as writing the code to a file and %INCLUDING the file.

Re: macro variable in macro name

yabwon — Wed, 19 May 2021 17:14:30 GMT

One approach could be as follows:



%let macroname=temp;

%sysmacdelete &macroname. / nowarn;

data _null_;
length code $ 32767; 
retain code " ";

input;
 code = catx(" ",code,_infile_);

 if _N_ = 2 then code = catx(" ", code, symget("macroname"));

 if strip(_infile_) =: '%mend' then 
  do;
    put code;
    rc = resolve(code);
  end;
cards4;
%macro 
/*&macroname.*/
(var1,var2);
%put Macro started: &SYSMACRONAME.;
%put ===============================;

/* macro code here */

%put Macro ended: &SYSMACRONAME.;
%put =============================;

%mend;
;;;;
run;

data _null_;
	attrib a format=1.;
	/* check log for the following message from the put statement */
	put "Macro ran successfully - delimiters (e.g. single/double quotes ok";
	a=%sysmacexist(&macroname.);
	put a=;
	if a=1 then
		put "&macroname. created successfully";
	else
		put "&macroname. not created - check for errors";
run;

Bart

Re: macro variable in macro name

yabwon — Wed, 19 May 2021 17:46:04 GMT

or even simpler:

data _null_;
length code $ 32767; 
code = '
(var1,var2);
%put Macro started: &SYSMACRONAME.;
%put ===============================;

/* macro code here */

%put Macro ended: &SYSMACRONAME.;
%put =============================;

%mend;
';
rc = resolve('%macro ' !! " &macroname." !! code);
run;