topic Re: Time comparison in New SAS User

Time comparison

Eliot1 — Wed, 05 Feb 2020 09:20:27 GMT

Hello All,

I would like to know if my traitement finish before 09:15 AM :

%let statut = OK;

data _null_;
call symput ('timenow',put (time(),hhmm.));
run;
%put &timenow;
--09:08

%macro tempsko;
%if '09:15't <= &timenow %then %do;
%let statut=KO;
%end;
%mend;
%tempsko;
%put &statut;

-- KO ???

Thx for your help

Re: Time comparison

Kurt_Bremser — Wed, 05 Feb 2020 09:30:09 GMT

Since timenow contains a string and not a number, a character comparison is used, and the single quote comes before any digit in the ASCII table. Make a time literal out of your timenow reference:

%let statut = OK;

data _null_;
call symput ('timenow',put (5000,hhmm.));
run;
%put &timenow;

options mprint mlogic symbolgen;

%macro tempsko;
%if '09:15't <= "&timenow"t %then %do;
%let statut=KO;
%end;
%mend;
%tempsko;
%put &statut;

Re: Time comparison

Satish_Parida — Wed, 05 Feb 2020 11:16:06 GMT

%let statut = OK;

data _null_;
call symput ('timenow',put (time(),hhmm.));
run;
%put &timenow;


%macro tempsko;
	data _null_;
	if '09:15't le "&timenow"t then call symput('statut','KO');
	run;
%mend;
%tempsko;

%put &statut;

Please let us know if this worked for you.

Re: Time comparison

Tom — Wed, 05 Feb 2020 18:00:05 GMT

The implied %EVAL() function call of the %IF statement does not recognize date/time/datetime literals. Make an explicit call to %SYSEVALF() instead. Also you are comparing the string 09:80 to the time value '09:15't.

%if %sysevalf('09:15't <= "&timenow"t) %then %do;

Re: Time comparison

Eliot1 — Mon, 30 Mar 2020 15:17:56 GMT

Sorry, it does not work.

Une nouvelle formulation serait : Comment puis-je tester si mon traitement est passé avant 09:15 AM

Thx for tour time

Re: Time comparison

Eliot1 — Mon, 30 Mar 2020 15:19:00 GMT

Sorry, it does not work.

A new formulation would be:

How can I test if my treatment is passed before 09:15 AM

Thx for tour time

Re: Time comparison

PaigeMiller — Mon, 30 Mar 2020 15:32:34 GMT

DO NOT format macro variables.

%let statut = OK;

data _null_;
call symput ('timenow',time()); /* NOTE: unformatted */
run;

%macro tempsko;
%if '09:15't <= &timenow %then %do;
%let statut=KO;
%end;
%mend;
%tempsko
%put &=statut;

Re: Time comparison

Tom — Mon, 30 Mar 2020 15:36:25 GMT

Show more details of what code you are using.

Re: Time comparison

Eliot1 — Tue, 31 Mar 2020 12:52:29 GMT

It does not work 😞

Re: Time comparison

Eliot1 — Tue, 31 Mar 2020 12:51:21 GMT

%let statut=OK;
%put &statut;

data _null_;
call symput ('timenow', time());
run;
%put &timenow;

%macro tempsko;
%if '14:40't <= &timenow %then %do;
%let statut=KO;
%end;
%mend;

%tempsko;

%put &statut;

Re: Time comparison

PaigeMiller — Tue, 31 Mar 2020 13:04:42 GMT

@Eliot1 wrote:

It does not work 😞

Explain, please.

Re: Time comparison

Eliot1 — Tue, 31 Mar 2020 14:13:30 GMT

This code work :

%let statut = OK;
%put &statut;

data _null_;
call symput ('timenow', time());
run;

%macro tempsko;
%if %sysevalf('09:15't <= &timenow) %then %do;
%let statut=KO;
%end;
%mend;

%tempsko;

%put &statut;

Thx all for your help

Re: Time comparison

Tom — Tue, 31 Mar 2020 14:19:02 GMT

@PaigeMiller %EVAL() does not treat time (or other) literals as special cases, it just treats them as text strings. You need to explicitly call %SYSEVALF() instead of letting SAS do an implicit call to %EVAL().