topic Trouble with SUBSTR function in New SAS User

Trouble with SUBSTR function

marleeakerson — Mon, 24 Feb 2020 18:06:05 GMT

Hello,

I am trying to extract the month from a date value that looks like this

Date1

20080201

20080301

20080401

and I want to create a new variable that is

Date2

So i tried using

Date2=SUBSTR(Date1, 5, 2);

But it did not work. Can you help?

Re: Trouble with SUBSTR function

tomrvincent — Mon, 24 Feb 2020 18:10:01 GMT

Put Date1 into a char variable before you substr.

Re: Trouble with SUBSTR function

marleeakerson — Mon, 24 Feb 2020 18:11:27 GMT

How do I do that?

Re: Trouble with SUBSTR function

tomrvincent — Mon, 24 Feb 2020 18:13:29 GMT

To convert numeric values to character, use the PUT function

Re: Trouble with SUBSTR function

PeterClemmensen — Mon, 24 Feb 2020 18:14:04 GMT

phrases like 'it did not work' does not help us much. What differs from what you expect? What does the log say?

Help us help you 🙂

Re: Trouble with SUBSTR function

Tom — Mon, 24 Feb 2020 18:21:23 GMT

Do you have a character variable? Or a numeric? If a numeric does it have date values? Or just numbers like 20,200,801?

data have;
  input
   @1 date yymmdd8.
   @1 char $8.
   @1 num 
  ;
  format date yymmdd10.;
cards;
20080201
20080301
20080401
;

data want;
  set have;
  month_date = month(date);
  month_char = substr(char,5,2);
  month_num = int(mod(num,1E4)/1E2);
run;

                                             month_    month_    month_
Obs          date      char         num       date      char       num

 1     2008-02-01    20080201    20080201       2        02         2
 2     2008-03-01    20080301    20080301       3        03         3
 3     2008-04-01    20080401    20080401       4        04         4

In general it is easier/clearer to work with actual date values. So perhaps you want to convert character or non-date numerics to date first.

data want;
  set have;
  month_date = month(date);
  month_char = month(input(char,yymmdd8.));
  month_num = month(input(put(num,z8.),yymmdd8.));
run;

Re: Trouble with SUBSTR function

Kurt_Bremser — Mon, 24 Feb 2020 21:37:07 GMT

Since it is a date value (as you posted), just use the month() function.