topic Re: Make row values into column in New SAS User

Make row values into column

podarum — Fri, 14 Feb 2020 20:40:11 GMT

Hi, I have a list of accounts and their customer Ids, some accounts can have more than 1 customer and different customer types. I would like to transpose by type of customer. Here's what I mean:

HAVE

Acct Type_A Type_B Type_C

001 123 234

001 123 356

002 567 124 345

002 567 124 678

WANT

Acct Type_A Type_B1 Type_B2 Type_C1 Type_C2

001 123 234 356

002 567 124 345 678

This logic applied to a list of 1 million accouts.

thanks

Re: Make row values into column

novinosrin — Fri, 14 Feb 2020 21:00:26 GMT

Hi @podarum Assuming I understand the req.

data have;
infile cards truncover;
input Acct   $   Type_A     Type_B     Type_C;
cards;
001          123            234      
001          123            356 
002          567            124           345
002          567            124           678
;
data temp;
 set have;
 by acct;
 if first.acct then grp=0;
 grp+1;
 array t type_:;
 do over t;
  vn=vname(t);
  v=t;
  output;
 end;
 drop type_:;
run;

proc sort data=temp out=temp2 nodupkey;
by acct vn v;
run;

proc transpose data=temp2 out=want(drop=_:);
by acct;
id vn grp;
var v;
run;

Re: Make row values into column

podarum — Fri, 14 Feb 2020 21:10:13 GMT

You Rock.. Thank You !!!