topic Re: creation of dummy with multiple observations in New SAS User

creation of dummy with multiple observations

amanjot_42 — Mon, 03 Feb 2020 05:23:06 GMT

Hi guys,

I am trying to create a dummy where the year is equal to the audit year. There are multiple observations for a particular firm.

Firm ID  Year    Audit_year        Dummy (what I want)
11      1990       .                   0
11      1991       .                   0 
11      1992   1993                    0
11      1993       .                   1
11      1993       .                   1
11      1993       .                   1
11      1994   1995                    0
11      1995       .                   1  
11      1996       .                   0
12      2001       .                   0
12      2002   2003                    0
12      2003      .                    1
12      2004      .                    0
12     2005       .                    0
12     2006       .                    0
12     2007       .                    0
12     2008       .                    0
12     2009       .                    0

In the latter table, audit years are one year ahead of YEAR. Please help with respect to the codes

Regards,
Amanjot

Re: creation of dummy with multiple observations

PeterClemmensen — Mon, 03 Feb 2020 05:36:07 GMT

data have;
input FirmID Year Audit_year;
datalines;
11 1990 .
11 1991 .
11 1992 1993
11 1993 .
11 1993 .
11 1993 .
11 1994 1995
11 1995 . 
11 1996 .
12 2001 .
12 2002 2003
12 2003 .
12 2004 .
12 2005 .
12 2006 .
12 2007 .
12 2008 .
12 2009 .
;

data want(drop=_:);
   merge have
         have (firstobs=2 keep=FirmID Year rename=(FirmID=_FirmID Year=_Year));
   dummy = FirmID = _FirmID & Audit_year = _Year;
run;

Result:

FirmID Year  Audit_year dummy 
11     1990  .          0 
11     1991  .          0 
11     1992  1993       1 
11     1993  .          0 
11     1993  .          0 
11     1993  .          0 
11     1994  1995       1 
11     1995  .          0 
11     1996  .          0 
12     2001  .          0 
12     2002  2003       1 
12     2003  .          0 
12     2004  .          0 
12     2005  .          0 
12     2006  .          0 
12     2007  .          0 
12     2008  .          0 
12     2009  .          0

Re: creation of dummy with multiple observations

ed_sas_member — Mon, 03 Feb 2020 08:25:55 GMT

Hi @amanjot_42

Here is an attempt to do this:

data want (drop = _Audit_year);
	set have;
	if Audit_year ne . then _Audit_year=0;
	_Audit_year + Audit_year;
	if _Audit_year = Year then Dummy = 1;
	else Dummy = 0;
run;

Output

Re: creation of dummy with multiple observations

Astounding — Mon, 03 Feb 2020 08:32:39 GMT

data want;
set have;
by firmID;
if first.firmID or audit_year > . then wanted = audit_year;
dummy = year = wanted > . ;
drop wanted;
retain wanted;
run;