SAS Infomap

Madhu_Kappala — Mon, 27 Jan 2020 06:39:20 GMT

Hi All,

Could you please suggest me how to find the list of SAS Info maps that are created by an Table.

For example the table name is cars from sashelp, i would like to know what are all the Info maps created using cars table.

any suggestions or help would be appreciated.

Thanks

Madhu

Re: SAS Infomap

ChrisHemedinger — Mon, 27 Jan 2020 17:37:08 GMT

Hi @Madhu_Kappala,

You can back into it, I think, by finding all of the information maps first, then using PROC INFOMAPS to list the tables.

Example:

/* Specify your metadata folder here.  This is the folder that     */
/* contains the information map definitions                        */
%let folder = /Shared Data/Maps;

/* NOTE: when using this LIBNAME statement in a batch environment,  */
/* you might need to add metadata host and credentials information. */
/* When running from SAS Enterprise Guide, it should not be         */
/* necessary; your metadata identity will be used automatically.    */
/* Note that the report will contain only those Information Maps    */
/* for which you have Read access permissions.                      */
libname imaps infomaps 
  mappath="&folder"
  aggregate=yes
  /* use already-established metadata connection */
  metacredentials=no
  /* uncomment the following if running in batch/DMS */
  /*****************   
  host=metadatahost.com
  port=8561
  user=yourId
  pw="yourPassword"
  ******************/
  PRESERVE_MAP_NAMES=YES;

footnote;
/* Report of information maps in the selected folder */
proc print data=sashelp.vinfomp noobs label;
  var mapname description;
  label mapname = "Name" description = "Description";
  title "Information Maps in &folder";
run;

Example result:

Then PROC INFOMAPS:

proc infomaps;
 update infomap "Cars" mappath="/Shared Data/Maps";
 list datasources;
run;

Example output:

Total datasources: 1
Data source: Sample Data.CARS_1993
ID: CARS_1993
Name: CARS_1993
Description:

Re: SAS Infomap

Madhu_Kappala — Tue, 28 Jan 2020 11:49:44 GMT

Thanks for the help @ChrisHemedinger

topic Re: SAS Infomap in New SAS User

SAS Infomap

Re: SAS Infomap

Re: SAS Infomap