topic Re: use of informat in New SAS User

use of informat

Arpit2 — Wed, 22 Jan 2020 15:55:58 GMT

i got stuck in this problem and it is not showing sas format date value .

data out;
input CALL_NO 1-3
 DATE 5-12
TRUCKS 14-15
ALARM 17;
informat date mmddyy8.;
datalines;
001 10/21/94 03 2
002 10/23/94 01 1
003 11/01/94 11 3
;
run;

Re: use of informat

novinosrin — Wed, 22 Jan 2020 15:59:40 GMT


data out;
input CALL_NO 1-3
 @5 DATE mmddyy8.
TRUCKS 14-15
ALARM 17;
format date mmddyy8.;
datalines;
001 10/21/94 03 2
002 10/23/94 01 1
003 11/01/94 11 3
;
run;

Re: use of informat

Reeza — Wed, 22 Jan 2020 16:01:02 GMT

INFORMATS are the input format, what a variable currently looks like.
FORMATS control the display of the output data.

You will not "see" an informat, but your data will be read in correctly. Try adding a FORMAT statement and you should get what you need.

Re: use of informat

FreelanceReinh — Wed, 22 Jan 2020 16:21:42 GMT

Hi @Arpit2 and welcome to the SAS Support Communities!

The documentation "INPUT Statement: Column" says: "To read with column input, data values must ... consist of standard numeric form or character form." So, date values in the form "mm/dd/yy" preclude column input. Just switch to list input by deleting the column specifications (1-3, ..., 17) in your DATA step. The suggested FORMAT statement is useful for displaying the date values, but not necessary for reading the raw data.

Re: use of informat

Tom — Wed, 22 Jan 2020 20:04:28 GMT

You cannot use column mode input statement and an INFORMAT. You will need to either read the value as character and use INPUT() function to generate the date value. Or read at least that one field using formatted mode input instead.

data out;
  input
    CALL_NO 1-3
    @5 DATE mmddyy8.
    TRUCKS 14-15
    ALARM 17
  ;
  format date mmddyy10.;
datalines;
001 10/21/94 03 2
002 10/23/94 01 1
003 11/01/94 11 3
;

Or if you are positive that every variable has a value (or when missing a period) then use list mode input. In that case you can either use the INFORMAT statement to set the informat for the variable or include the informat in the input statement but add the : modifier so that it still does list mode input.

data out;
  input
    CALL_NO
    DATE :mmddyy8.
    TRUCKS 
    ALARM 
  ;
  format date mmddyy10.;
datalines;
001 10/21/94 03 2
002 10/23/94 01 1
003 11/01/94 11 3
;

PS Do NOT use only two digits for year values.