topic Add one variable as observations to another variable in New SAS User

Add one variable as observations to another variable

dapenDaniel — Thu, 09 Jan 2020 19:05:20 GMT

Hi SAS masters,

I have two datasets below. FirmID and Year are the same.

Have1

FirmID Year Variable1

1001 1995 AA

1001 1996 BB

1001 1997 CC

1002 1992 DD

1002 1993 EE

1002 1994 FF

Have2

FirmID Year Variable2

1001 1995 GG

1001 1996 HH

1001 1997 II

1002 1992 JJ

1002 1993 KK

1002 1994 LL

I would like to add variable1 as observations to variable2 and expect the data like below.

FirmID Year Variable1_2

1001 1995 GG

1001 1995 AA

1001 1996 HH

1001 1996 BB

1001 1997 II

1001 1997 CC

1002 1992 DD

1002 1992 JJ

1002 1993 EE

1002 1993 KK

1002 1994 FF

1002 1994 LL

what code do I need to use? Thanks.

Re: Add one variable as observations to another variable

novinosrin — Thu, 09 Jan 2020 19:11:48 GMT

proc sql;
create table want as
select FirmID, Year, Variable1 as Variable1_2
from
(select * from have1
union all
select * from have2)
order by firmid,year;
quit;

Re: Add one variable as observations to another variable

PeterClemmensen — Thu, 09 Jan 2020 19:14:51 GMT

data have1;
input FirmID Year Variable1 $;
datalines;
1001 1995 AA 
1001 1996 BB 
1001 1997 CC
1002 1992 DD 
1002 1993 EE
1002 1994 FF
;

data have2;
input FirmID Year Variable2 $;
datalines;
1001 1995 GG
1001 1996 HH
1001 1997 II
1002 1992 JJ
1002 1993 KK
1002 1994 LL
;

data want;
	set have2 (rename=Variable2=Variable1_2); output;
	set have1 (rename=Variable1=Variable1_2); output;
run;

Re: Add one variable as observations to another variable

Tom — Thu, 09 Jan 2020 20:33:27 GMT

Just rename it on the way in.

data want ;
  set have1(rename=(variable1=variable1_2))
      have2(rename=(variable2=variable1_2))
  ;
run;

If the data was already sorted by FIRMID YEAR you can add a BY statement and the result will still be sorted.

data want ;
  set have1(rename=(variable1=variable1_2))
      have2(rename=(variable2=variable1_2))
  ;
  by firmid year ;
run;