topic Re: proc means - data not outputed in New SAS User

proc means - data not outputed

radhikaa4 — Wed, 25 Dec 2019 23:32:53 GMT

Hi I currently have a data set where I am trying to get the proc means for all numeric variables - n, mean, median, std, min, max, and confidence intervals

Here is the code I wrote:

proc means data=test n mean lclm uclm alpha=0.05 median min max missing ;
output out=test_stat;
by group;
var
time1 time2 time3 time4;
run;

The code works in the result viewer but when i look at test_stat (it has not included upper and lower confidence intervals)

Any help would be great!

Thanks

Re: proc means - data not outputed

novinosrin — Wed, 25 Dec 2019 23:55:18 GMT

ods output summary=test_stat(drop=_control_);

proc means data=test n mean lclm uclm alpha=0.05 median min max missing stackodsoutput ;
by group;
var
time1 time2 time3 time4;
run;

stackodsoutput

Re: proc means - data not outputed

PaigeMiller — Thu, 26 Dec 2019 00:35:54 GMT

proc means data=test;
by group;
var time1 time2 time3 time4;
output out=test_stat  n= mean= lclm= uclm= median= min= max= missing=/autoname; 
run;

Re: proc means - data not outputed

ed_sas_member — Thu, 26 Dec 2019 10:38:15 GMT

Hi @radhikaa4

In the OUTPUT statement, you need to specify the column name to retrieve each statistic :

output out=test_stat n= mean= median= std= min= max= lclm= uclm= / autoname;

You can also personalize the names of the new columns, e.g.:

output out=test_stat n=(n_time1 n_time2 n_time3 n_time4) ...;

NB: in the VAR Statement, you can put _NUMERIC_ to mention all numeric variables instead of time1 time2 time3 time4, assuming there is no other numeric variable in your input dataset.