topic Re: Data in single row, need in multiple rows in New SAS User

Data in single row, need in multiple rows

shikhar6339 — Tue, 10 Dec 2019 11:47:11 GMT

Data I have:

1 A,B,C

2 D

3 E,F

Data I want:

1 A

1 B

1 C

2 D

3 E

3 F

Re: Data in single row, need in multiple rows

Kurt_Bremser — Tue, 10 Dec 2019 11:49:44 GMT

data want;
set have;
do i = i to countw(string,',');
  newstring = scan(string,i,',');
  output;
end;
drop i string;
run;

Set proper length for newstring as needed.

Re: Data in single row, need in multiple rows

PeterClemmensen — Tue, 10 Dec 2019 11:51:41 GMT

Welcome to the SAS Community 🙂

data have;
input id var $20.;
datalines;
1 A,B,C
2 D
3 E,F
;

data want(keep=id newvar);
    set have;
    do i=1 to countw(var, ',');
        newvar=scan(var, i, ',');
        output;
    end;
run;

Result:

id  newvar
1   A
1   B
1   C
2   D
3   E
3   F

Re: Data in single row, need in multiple rows

Ksharp — Tue, 10 Dec 2019 11:59:59 GMT

data have;
infile cards dlm=' ,' truncover;
input id var : $40. @;
do while(not missing(var));
 output;
 input var : $40. @;
end;
datalines;
1 A,B,C
2 D
3 E,F
;