topic Re: Conversion From Numeric to Words Format in Indian Currency in New SAS User

Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Fri, 22 Nov 2019 12:55:30 GMT

Hi Guys,

Suppose I have data like this.

DATA HAVE;

X=100000;

Y=1000000;

Z=1500000;

RUN;

and so on.

I want these numbers to be presented in a word format like

The value of X Would be One Lakh, Y Would be like Ten Lakh

In SAS I have tried WORD. and WORDS. Format,But all these formats are giving Output like

X=one hundred thousand

Y=one million.

Also attaching the screenshot of the output from functions I have used i.e. Words.

I want the output in Indian Format.

Re: Conversion From Numeric to Words Format in Indian Currency

PeterClemmensen — Fri, 22 Nov 2019 12:58:21 GMT

Hi and welcome to the SAS Community 🙂

Do you want to create a new character variable to hold this value or simply format the existing numeric value?

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Fri, 22 Nov 2019 13:01:01 GMT

You can give either Both are acceptable to me.
But former would be preferable

Re: Conversion From Numeric to Words Format in Indian Currency

PeterClemmensen — Fri, 22 Nov 2019 13:07:10 GMT

Using a picture format..

proc format;
    picture ind other='00009 Lakh' (mult=.00001);
run;

data have;
    x=100000;
    y=1000000;
    z=1500000;
    format x y z ind.;
run;

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Fri, 22 Nov 2019 13:17:50 GMT

Thank for the Reply .
But What if X is like
X=1321462

Re: Conversion From Numeric to Words Format in Indian Currency

PeterClemmensen — Fri, 22 Nov 2019 14:09:58 GMT

What would you like the format to return then?

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Sat, 23 Nov 2019 16:43:04 GMT

I want the output like this
IF X=1321462
OUTPUT=Thirteen lakh twenty-one thousand four hundred sixty two

Re: Conversion From Numeric to Words Format in Indian Currency

Patrick — Sun, 24 Nov 2019 07:57:53 GMT

Something like below could work. I haven't looked up what the next unit after lakh is so if your number can become that big then you would need to extend the function accordingly.

proc fcmp outlib=work.functions.myfuncs;
   function lakh_words(in_num) $;
      length lakh_words $150;
      _lakh=abs(int(in_num/100000));
      if _lakh>0 then
        do;
          if abs(in_num) ne in_num then
            do;
              lakh_words='minus';
              in_num=abs(in_num);
            end;
          lakh_words=catx(' ',lakh_words, put(_lakh,words60.),'lakh'
                          ,put((in_num- _lakh*100000),words150.)
                         );
        end;
      else
        lakh_words=put(in_num,words150.);

      return(lakh_words); 
   endsub;
run;
options cmplib=(work.functions);

/* Create a format using the function created by the FCMP procedure. */
proc format; 
  value lakh_words(default=150) 
    other=[lakh_words()]
  ; 
run;


data test;
  input numvar;
  datalines;
462
1462
21462
321462
1321462
51321462
51321462.3
-51321462.3
;

proc print data=test;
  format numvar lakh_words. ; 
  var numvar / style(data)=[textalign= left];
run;

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Sun, 24 Nov 2019 08:00:15 GMT

Thank You So much for the help.

The code worked like a charm.

The only Limitation I figured out that it didn't work for values in Crores, for that you already told to adjust the formulas.

Thanks Again.

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Sun, 24 Nov 2019 08:02:05 GMT

While using PROC FORMAT. It didn't let me choose the same name of the format i.e lakh_words.
So I used lakh_wordsA.

Re: Conversion From Numeric to Words Format in Indian Currency

PeterClemmensen — Sun, 24 Nov 2019 08:55:15 GMT

@Patrick very nice!

Re: Conversion From Numeric to Words Format in Indian Currency

Patrick — Sun, 24 Nov 2019 10:04:30 GMT

@aashish_jain

If I Googled that right then the units change by 10 power 2.

Below a code version which also covers crore and arab. If you need even more units then the only thing you should need to do is amending the array statement.

proc fcmp outlib=work.functions.myfuncs;
   function ind_num_terms(in_num) $;
      length ind_num_in_words $150;
      _in_num_abs=abs(in_num);

      _ind_num_part=int(_in_num_abs/100000);
      if _ind_num_part>0 then
        do;
          array ind_terms {3} $5 ('lakh','crore','arab');
          _units=ceil(length(strip(put(_ind_num_part,16.)))/2);
          _remainder=_ind_num_part;
          do _i=min(_units,dim(ind_terms)) to 1 by -1;
            ind_num_in_words=catx(' ',ind_num_in_words,put(int(_remainder/100**(_i-1)),words60.),ind_terms[_i]);
            _remainder=_remainder-int(_remainder/100**(_i-1))*(100**(_i-1));
          end;
          ind_num_in_words=catx(' ',ifc(_in_num_abs=in_num,' ','minus')
                                ,ind_num_in_words,put((_in_num_abs- _ind_num_part*100000),words150.)
                                );
        end;
      else
        ind_num_in_words=put(in_num,words150.);
      return(ind_num_in_words); 
   endsub;
run;
options cmplib=(work.functions);

/* Create a format using the function created by the FCMP procedure. */
proc format; 
  value ind_num_terms(default=150) 
    other=[ind_num_terms()]
  ; 
run;


data test;
  input numvar;
  datalines;
1
21
321
4321
54321
654321
7654321
87654321
987654321
1987654321
21987654321
-21462
-51321462
-51321462.3
;

proc print data=test;
  format numvar ind_num_terms.;
  var numvar / style(data)=[textalign= left];
run;

Re: Conversion From Numeric to Words Format in Indian Currency

aashish_jain — Sun, 24 Nov 2019 14:46:54 GMT

Thank you again for taking the time to figure out and making the code dynamic.