topic Re: Proc sgplot refline label in New SAS User

Proc sgplot refline label

liangjz — Mon, 21 Oct 2019 17:59:20 GMT

proc sql;

create table myclass as

select age,height,mean(height) as mHeight

from sashelp.class

;

quit;

proc sgplot data=myclass;

scatter x=age y=height;

refline 14 /axis=x labelloc=inside label="The Reference Line" lineattrs=(color=green);

run;

Is it possible to change the label “The reference Line” from horizontal to vertical?

Re: Proc sgplot refline label

PGStats — Mon, 21 Oct 2019 19:21:27 GMT

I can't find any option to rotate the label. SG-Annotation is the next best thing, but rather clumsy. You might also consider a compromise such as:

proc sgplot data=myclass;
  scatter x=age y=height;
  refline 14 /axis=x labelloc=inside  label="Reference/Line"  
  	lineattrs=(color=green) labelpos=min splitchar="/";
run;

after all, horizontal is always easier to read.

Re: Proc sgplot refline label

liangjz — Mon, 21 Oct 2019 20:02:03 GMT

Hi PG,

Thanks for the info you posted -- agreed with you, with splitting label, it is nice. I don't have to use annotation.

Best,

John

Re: Proc sgplot refline label

ballardw — Mon, 21 Oct 2019 20:53:44 GMT

Or add a data point or two and use a TEXT plot.

proc sql;
create table work.myclass as
   select age,height,mean(height) as mHeight
   from sashelp.class
;
quit;
data work.label;
   age=14.2;
   y=70;
   Labeltext= "The Reference Line";
run;
 
data work.plot;
   set work.myclass
       work.label;
run;
proc sgplot data=work.plot;
  scatter x=age y=height/ name='scatter';
  refline 14 /axis=x labelloc=inside  label="" lineattrs=(color=green);
  text x=age y=y text=labeltext /rotate=90 name='text';

  keylegend 'scatter';

run;

Changing the Rotate angle to =90 will make it read from top to bottom. Adjust the x and y coordinates to be "nice". There are also some text appearance options available with a Text plot, such as BACKLIGHT not available in REFLINE.

Re: Proc sgplot refline label

liangjz — Tue, 22 Oct 2019 15:28:03 GMT

Thanks, ballardw. Text plot is much easier than annotation in this case for me at least. I really appreciate it.