topic output previous row in New SAS User

output previous row

eduard1231 — Sun, 20 Oct 2019 01:19:11 GMT

This is the sample code

data a_k resid;
set akkk;
if mad_command ne 0 then do; output resid and ....; end;
run;

So, what I am trying to do is that if mad_command ne 0, then ouput the whole row to resid table AND ALSO OUTPUT the previous row to resid table as well.

Thanks

Re: output previous row

novinosrin — Sun, 20 Oct 2019 01:42:44 GMT

Hello @eduard1231

Are you asking for this kinda logic?


data have;
input var ;
cards;
0
0
4
1
2
;


data want;
set have;
if var ne 0 then do;
output;
n=_n_-1;
set have point=n;
output;
end;
run;

Re: output previous row

mkeintz — Sun, 20 Oct 2019 01:49:10 GMT

This is where using the POINT= option of the SET statement helps:

data a_k resid;
  set akkk;
  output a_k;

  if mad_command ne 0 then do; 
    output resid;
    p=_n_-1;
    set akkk point=p;
    output resid;
  end;
run;

This program outputs every akkk record to dataset a_k. If outputs the selected record, and its predecessor to resid. Note the original preceding record now follows the precipitating record. If instead you want to preserve the original order, you can:

data a_k resid;
  set akkk;
  output a_k;

  if mad_command ne 0 then do p=_n_-1 to _n_;
    set akkk point=p;
    output resid;
  end;
run;